如何在gradle中为不同的sourceCompatibility和targetCompatibility构建项目

Question

我当前在 gradle 文件中的配置是

sourceCompatibility = 1.7
targetCompatibility = 1.7

该规范使我的项目特定于 java 1.7。

我的要求是我应该能够为不同的java版本构建我的项目，例如java 1.7和java 1.8

PS：就像在 gradle 中构建配置文件一样，我们可以指定不同的 java 版本。

Answer 1

Gradle 使用它在 PATH 或 JAVA_HOME 中找到的任何 JDK。因此，如果删除 sourceCompatibility 和 targetCompatibility，它应该使用项目运行的计算机上使用的 Java 版本来构建项目。当然，这确实意味着您不应该在代码中使用 lambda 之类的构造，否则 Java 7 上的编译将会失败。

您还应该注意，从 Gradle 5 开始，对 Java 7 的支持将被删除，并且它将仅在 Java 8（或更高版本）上运行。

另一种方法是在运行时指定 JDK，请参阅此链接

如果你想同时构建多个 Java 版本，你可以使用如下内容：

task compile7(type: JavaCompile) {
   source = fileTree(dir: 'src', include: '**/*.java')
   classpath = sourceSets.main.compileClasspath
   sourceCompatibility = 1.7
   targetCompatibility = 1.7
   destinationDir = file('build/java7')
}
task jar7(type: Jar, dependsOn: compile7) {
   from('build/java7')
   archiveName = 'project-JDK7.jar'
   destinationDir = file('build/jars')
}
task compile8(type: JavaCompile) {
   source = fileTree(dir: 'src', include: '**/*.java')
   classpath = sourceSets.main.compileClasspath
   sourceCompatibility = 1.8
   targetCompatibility = 1.8
   destinationDir = file('build/java8')
}
task jar8(type: Jar, dependsOn: compile8) {
   from('build/java8')
   archiveName = 'project-JDK8.jar'
   destinationDir = file('build/jars')
}

您可以调用gradle jar7 jar8为您想要的两个 java 版本构建 jar。当然，上面的代码可以改进以参数化操作，如下所示：

ext.javaVer = project.hasProperty('javaVer') ? project.getProperty('javaVer') : '1.7'
task compileJ(type: JavaCompile) {
   source = fileTree(dir: 'src', include: '**/*.java')
   classpath = sourceSets.main.compileClasspath
   sourceCompatibility = javaVer
   targetCompatibility = javaVer
   destinationDir = file('build/' + javaVer)
}
task jarJ(type: Jar, dependsOn: compileJ) {
   from('build/' + javaVer)
   archiveName = 'project-' + javaVer + '.jar'
   destinationDir = file('build/jars')
}

使用这种格式，您可以为 Java 8 和 Java 7调用gradle jarJ -P javaVer=1.8和进行构建。gradle jarJ