在运行时使用tclientdataset组件的参数声明事件处理程序的正确方法是什么

Question

我试图在运行时在窗体中定义ClientDataSet组件.我可以成功定义所有字段并在VCL表单程序中操作ClientDataSet,但是当我尝试将诸如AfterInsert之类的事件的事件处理程序添加到代码中时,编译器会对应于我的格式.

clientDataset在此过程中创建:

procedure TForm1.CreateNestedDataSets;
begin

  cdsTables := TClientDataSet.Create(Self);
  cdsNotes := TClientDataSet.Create(cdsTables); //nested dataset
  //Define Tables
  with TFloatField.Create(Self) do
  begin
    Name := 'TblID';
    FieldKind := fkData;
    FieldName := 'ID';
    DataSet := cdsTables;
    Required := True;
  end;

  ...  //define other fields for cdsTables  & nested clientdataset cdsNotes

  cdsNotes.AfterInsert := cdsNotesAfterInsert(cdsNotes: TDataSet);

  //Create the ClientDataSet and its nested datasets
  cdsTables.CreateDataSet;

  //This is problem code line:
  cdsNotes.AfterInsert := cdsNotesAfterInsert;


  //Configure the DataSources
  dsTables.DataSet := cdsTables;
  dsNotes.DataSet := cdsNotes;
end;

各种论坛讨论都提出了这个例子的方法:

MyLabel := TLabel.Create(self);
MyLabel.OnClick := MyLabelClick;

在AfterInsert的情况下,包含一个参数.如果我在设计时生成事件,Delphi会生成:

procedure TForm1.ClientDataSet1AfterInsert(DataSet: TDataSet);

试图复制上面的建议我尝试了这种方法生成编译器错误:

cdsNotes.AfterInsert := cdsNotesAfterInsert; 不兼容的类型参数列表不同

其他格式也会产生错误:

cdsNotes.AfterInsert := cdsNotesAfterInsert(DataSet: TDataSet); 实际参数太多

我已尝试其他变种与错误消息的assor.这是我第一次尝试定义一个事件,我不确定我是否理解如何处理该声明.我相信我声明实现事件的实际过程'cdsNotesAfterInsert'不需要任何参数,因为它绑定
到clientdataset cdsNotes.如果我错了,请纠正我.

这是一个包含违规代码的完整表单单元

    unit ForumTest;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Data.DB, DBClient;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    cdsTables : tclientDataset;
    cdsNotes :tclientDataset;
    procedure CreateNestedDataSets;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
procedure TForm1.CreateNestedDataSets;
begin

  cdsTables := TClientDataSet.Create(Self);
  cdsNotes := TClientDataSet.Create(cdsTables);
  //Define Tables
  with TFloatField.Create(Self) do
  begin
    Name := 'TblID';
    FieldKind := fkData;
    FieldName := 'ID';
    DataSet := cdsTables;
    Required := True;
  end;
  with TFloatField.Create(Self) do
  begin
    Name := 'TblParentID';
    FieldKind := fkData;
    FieldName := 'Parent';
    DataSet := cdsTables;
    Required := false;
  end;
  with TStringField.Create(Self) do
  begin
    Name := 'TblTitle';
    FieldKind := fkData;
    FieldName := 'Title';
    Size := 40;
    DataSet := cdsTables;
    Required := True;
  end;
  with TStringField.Create(Self) do
  begin
    Name := 'TblFilename';
    FieldKind := fkData;
    FieldName := 'Filename';
    Size := 80;
    DataSet := cdsTables;
    Required := False;
  end;
  //Note: For TDataSetFields, FieldKind is fkDataSet by default
  with TDataSetField.Create(Self) do
  begin
    Name := 'TblNotes';
    FieldName := 'NestedDataSet';
    DataSet := cdsTables;
  end;

  //Define Notes
  cdsNotes.DataSetField := TDataSetField(FindComponent('TblNotes'));
  with TFloatField.Create(Self) do
  begin
    Name := 'NoteID';
    FieldKind := fkData;
    FieldName := 'Note ID';
    DataSet := cdsNotes;
    Required := True;
  end;
  with TStringField.Create(Self) do
  begin
    Name := 'NoteTxt';
    FieldKind := fkData;
    FieldName := 'Notes';
    DataSet := cdsNotes;
    Size := 40;
  end;
  cdsNotes.AfterInsert := cdsNotesAfterInsert(cdsNotes: TDataSet);
  //Create the ClientDataSet and its nested datasets
  cdsTables.CreateDataSet;
  //Configure the DataSources
  dsTables.DataSet := cdsTables;
  dsNotes.DataSet := cdsNotes;

end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  CreateNestedDataSets;
end;

end.

Answer 1

这是专门回答您关于如何将一些自编代码分配给TClientDataSet的AfterInsert事件属性的观点.

如果在在线帮助中查找TClientDataSet.AfterInsert,您将看到它被定义为TDataSetNotifyEvent,而后者又被定义为

type TDataSetNotifyEvent = procedure(DataSet: TDataSet) of object

这个过程的意义of object在于,过程必须是一个对象的方法(读取"类"),而不是您在评论中描述的独立过程/方法.

要与TDataSetNotifyEvent分配兼容,您的过程需要具有匹配的代码"signature",也就是说,它必须是类的过程(不是类的函数)并且具有完全相同的参数,在这种情况下单个TDataSet参数.

所以你需要的就是这样

type
  TForm1 = class(TForm)
    ClientDataSet1: TClientDataSet;
    procedure FormCreate(Sender: TObject);
  protected
    procedure MyInsertHandler(ADataSet : TDataSet);
  end;

[...]

procedure TForm1.FormCreate(Sender: TObject);
begin
  ClientDataSet1.AfterInsert := MyInsertHandler;
end;

procedure TForm1.MyInsertHandler(ADataSet: TDataSet);
begin
  // Your code goes here, e.g.
  Caption := ADataSet.Name + ' after insert';
end;

就那么简单.