使用基于%pass/fail子作业的Groovy脚本设置Jenkins multijob构建结果

Question

我有一个非常简单的Jenkins Multijob项目:

• 多椎
  • 儿童工作1
  • 儿童工作2
  • 儿童工作3
  • childjob 4等......

我想设置Multijob状态如下:

• 如果所有子女工作都通过,我想要一个绿球
• 我想要一个黄色的球,如果有任何跳过或<25%失败
• 如果> = 25%失败,我想要一个红球

我知道我可以使用带有如下脚本的Groovy post构建操作,但我不知道如何设置所需的阈值级别:

void log(msg) {
manager.listener.logger.println(msg)
}

threshold = Result.SUCCESS

void aggregate_results() {
    failed = false

    mainJob = manager.build.getProject().getName()
    job = hudson.model.Hudson.instance.getItem(mainJob)

    log '-------------------------------------------------------------------------------------'
    log 'Aggregated status report'
    log '-------------------------------------------------------------------------------------'

log('${mainJob}    #${manager.build.getNumber()} - ${manager.build.getResult()}')

job.getLastBuild().getSubBuilds().each { subBuild->
  subJob = subBuild.getJobName() 
  subJobNumber = subBuild.getBuildNumber()
  job = hudson.model.Hudson.instance.getItem(subBuild.getJobName())
  log '${subJob}   #${subJobNumber} - ${job.getLastCompletedBuild().getResult()}'
  log job.getLastCompletedBuild().getLog()

  //println subBuild
  dePhaseJob = hudson.model.Hudson.instance.getItem(subBuild.getJobName())
  dePhaseJobBuild = dePhaseJob.getBuildByNumber(subBuild.getBuildNumber())
  dePhaseJobBuild.getSubBuilds().each { childSubBuild ->
    try {
        log '   ${childSubBuild.jobName}'

        job = hudson.model.Hudson.instance.getItem(childSubBuild.getJobName())
        build = job.getBuildByNumber(childSubBuild.getBuildNumber())

        indent = '  '    
        log '${indent} #${build.getNumber()}  - ${build.getResult()}' 
        log build.getLog()

        if(!failed && build.getResult().isWorseThan(threshold) ) {
          failed = true
        }
    } catch (Exception e) {    
        log('ERROR: ${e.getMessage()}')
        failed = true
    }
  }
}

if(failed) {manager.build.setResult(hudson.model.Result.FAILURE)}
}

try {
  aggregate_results()
} catch(Exception e) {
  log('ERROR: ${e.message}')
  log('ERROR: Failed Status report aggregation')
  manager.build.setResult(hudson.model.Result.FAILURE)
}

任何人都可以帮助调整脚本来实现我的需求吗？

Answer 1

不确定这是否真的符合答案。可能更多的是注释，但注释并不真正适合长代码片段，所以这里是。

为了使您的代码更具可读性和更容易理解，我做了以下操作：

• 用常规属性访问替换了 getXX 和 setYY 的所有实例，例如build.getResult()变成build.result
• 删除了函数调用中不必要的括号的使用，例如log('ERROR: ${e.getMessage()}')变成log 'ERROR: ${e.getMessage()}'
• 将单引号中的字符串插值替换为双引号，因为字符串插值在单引号中不起作用。例如 log 'ERROR: ${e.message}'变成log "ERROR: ${e.message}"
• 从声明脚本全局绑定范围中的所有变量切换为局部变量，例如subJob = ...变为def subJob = .... 在全局范围内声明所有内容会导致难以发现的问题，特别是如果您重复使用job.

我还清理了一些冗余的内容，例如：

job.getLastBuild().getSubBuilds().each { subBuild->
  subJob = subBuild.getJobName() 
  subJobNumber = subBuild.getBuildNumber()
  job = hudson.model.Hudson.instance.getItem(subBuild.getJobName())  // <---
  ...
  //println subBuild
  dePhaseJob = hudson.model.Hudson.instance.getItem(subBuild.getJobName()) // <---
  dePhaseJobBuild = dePhaseJob.getBuildByNumber(subBuild.getBuildNumber())

所以这里我们将job和都设置dePhaseJob为相同的值。像这样将相同的值分配给两个单独的变量是多余的，只会使代码更难以阅读。

此外（我对 jenkins 内部 api 不太熟悉，所以我在这里可能是错的）上面代码中的以下流程似乎关闭了：

• 我们有subBuild实例
• 然后我们将相应的作业实例检索到job和dePhaseJob
• 然后我们检索构建并dePhaseJobBuild使用dePHaseJob.getBuildByNumber(subBuild.buildNumer)

但这不就留给我们了吗subBuild == dePhaseJobBuild？也就是说，我们花费了所有这些代码只是为了检索我们已经拥有的值。我们从构建到工作，再回到构建。除非我在詹金斯 API 中遗漏了一些深奥的东西，否则这似乎也是多余的。

通过所有这些更改和其他一些小更改，我们得到了以下代码：

def job(name) {
  hudson.model.Hudson.instance.getItem(name) 
}

def aggregateResults() {
  def mainJobName = manager.build.project.name
  log '-------------------------------------------------------------------------------------'
  log 'Aggregated status report'
  log '-------------------------------------------------------------------------------------'
  log "${mainJobName}    #${manager.build.number} - ${manager.build.result}"

  def failed = false
  job(mainJobName).lastBuild.subBuilds.each { subBuild ->
    log "${subBuild.jobName}   #${subBuild.buildNumber} - ${subBuild.result}"
    log subBuild.log

    subBuild.subBuilds.each { subSubBuild ->
      try {
        log "   ${subSubBuild.jobName}   #${subSubBuild.buildNumber} - ${subSubBuild.result}"
        log "   " + subSubBuild.getLog(Integer.MAX_VALUE).join("\n   ") //indent the log lines

        if(!failed && subSubBuild.result.isWorseThan(threshold)) {
          failed = true
        }
      } catch (Exception e) {
        log "ERROR: ${e.message}"
        failed = true
      }
    }
  }

  if(failed) {
    manager.build.result = hudson.model.Result.FAILURE
  }
}

再说一遍，我没有詹金斯实例来测试这个，所以我在黑暗中飞行，并提前为拼写错误、语法错误或其他滥用代码和詹金斯 API 的行为道歉。

您的代码中的问题（例如我看不到曾经起作用的字符串插值问题）让我认为原始代码不起作用，而是一种示例模式。

这让我进一步想知道你是否真的需要在这里进行两层嵌套，即如下：

job(mainJobName).lastBuild.subBuilds.each { subBuild ->
  subBuild.subBuilds.each { subSubBuild ->
    ...
  }
}

真的有必要还是一级就足够了？从您问题中的快速图表来看，我们似乎只需要关心主要工作及其子工作，而不是子子工作。

如果是这种情况，您可以遵循以下逻辑：

def aggregateResults() {
  def mainJob = job(manager.build.project.name)
  def subs    = mainJob.lastBuild.subBuilds
  def total   = subs.size()
  def failed  = subs.findAll { sub -> sub.result.isWorseThan(threshold) }.size()

  if(failed > 0) {
    manager.build.result = hudson.model.Result.FAILURE
  }

  failed == 0 ? "green" : (failed/total < 0.25 ? "yellow" : "red")
}