有谁知道如何调用内部描述的子过程使用procedurepointer返回值.
我正在阅读ILE RPG手册并且卡在%PADDRBIF上,这让我可以获得程序的地址.例如,当动态决定我想要调用哪个procdure时,我可以使用if ... then ... else..endif和CALLP.但有没有办法将ifp外部化为if结构？像.NET中的委托,我可以在一个控件结构中定义委托并分配函数/ sub来调用.
我所知道的是如何定义PROCPTR以及如何在没有返回值的情况下调用过程.但是在处理返回值时我该怎么做.
以下是分配程序地址并调用程序itselfe的示例:
H**************************************************************************
H DEBUG DECEDIT('0,') DATEDIT(*DMY.) dftactgrp(*no)
H*
D**************************************************************************
D* Prototypes
D*-------------------------------------------------------------------------
D* -------------------------------------------------------------
D* Returns String 1
D* -------------------------------------------------------------
D GetStr1 pr 10a
D
D* -------------------------------------------------------------
D* Returns String 2
D* -------------------------------------------------------------
D GetStr2 pr 10a
D
D**************************************************************************
D* Definitions
D*-------------------------------------------------------------------------
D pPtrGetStr1 s * procptr
D pPtrGetSTr2 s * procptr
D string1 s 10a
D string2 s 10a
D
C**************************************************************************
C* M A I N P R O G R A M
C**************************************************************************
C
C eval pPtrGetStr1 = %paddr(GetStr1)
C eval pPtrGetStr2 = %paddr(GetStr2)
C
C eval string1 = GetStr1()
C eval string2 = GetStr2()
C
C string1 dsply
C string2 dsply
C
C move *on *inlr
P**************************************************************************
P* P R O C E D U R E S
P**************************************************************************
P* -------------------------------------------------------------
P* Returns String 1
P* -------------------------------------------------------------
P GetStr1 b
D GetStr1 pi 10a
D result s 10a
C movel 'string1' result
C return result
P GetStr1 e
P
P* -------------------------------------------------------------
P* Returns String 2
P* -------------------------------------------------------------
P GetStr2 b
D GetStr2 pi 10a
D result s 10a
C movel 'string2' result
C return result
P GetStr2 e
P**************************************************************************
提前致谢
差不多了:
您需要一个使用过程指针来解析动态过程的原型.
dcl-s pDynamicProc Pointer(*proc); // --2--
dcl-pr DynamicProc Char(25) ExtProc(pDynamicProc); // --1--
parm1 Char(10);
parm2 Char(10);
end-pr;
...
// Before you call it you need to set the pointer
if (some condition) then; // --3--
pDynamicProc = %paddr(Proc1);
else;
pDynamicProc = %paddr(Proc2);
endif;
// Here is the call
MyVariable = DynamicProc(p1: p2); // --4--
...
// ====================================================
// Procedure definitions
dcl-proc Proc1;
dcl-pi *n Char(25);
parm1 Char(10);
parm2 Char(10);
end-pi;
// Do something
end-proc;
// ====================================================
// Another procedure with the same procedure interface
dcl-proc Proc2;
dcl-pi *n Char(25);
parm1 Char(10);
parm2 Char(10);
end-pi;
// Do something else
end-proc;
这样您就不必搜索代码来确定发生了什么.DynamicProc是一个由过程指针解析的过程pDynamicProc.原型发现于// --1--.该ExtProc()关键字指定的程序指针,而不是一个程序的名字.指针定义于// --2--.在使用之前调用过程之前,DynamicProc必须使用过程地址填充指针.这发生在// --3--.现在你可以DynamicProc像任何其他程序一样打电话(参见参考资料// --4--).
请注意,我没有原型Proc1和Proc2.我不需要那些,除非我直接从模块外面调用它们.顺便说一句,基于之前的问题,您正在发布支持省略内部过程原型的版本.你应该停止编码固定格式的RPG.那些跟着你维护代码的人会感谢你.