构造复杂对象图的计算表达式

Question

给出以下类型:

type Trip = {
  From: string
  To: string
}

type Passenger = {
   Name: string
   LastName: string
   Trips: Trip list
}

我正在使用以下构建器:

type PassengerBuilder() = 
  member this.Yield(_) = Passenger.Empty

  [<CustomOperation("lastName")>]
  member __.LastName(r: Passenger, lastName: string) = 
    { r with LastName = lastName }

  [<CustomOperation("name")>]
  member __.Name(r: Passenger, name: string) = 
    { r with Name = name }

type TripBuilder() = 
  member __.Yield(_) = Trip.Empty

  [<CustomOperation("from")>]
  member __.From(t: Trip, f: string) = 
    { t with From = f }

  // ... and so on

创建类型的记录Passenger,如下所示:

let passenger = PassengerBuilder()
let trip = TripBuilder()

let p = passenger {
  name "john"
  lastName "doe"
}

let t = trip {
  from "Buenos Aires"
  to "Madrid"
}

我将如何组合PassengerBuilder和TripBuilder使我能够实现这种用法？

let p = passenger {
    name "John"
    lastName "Doe"
    trip from "Buenos Aires" to "Madrid"
    trip from "Madrid" to "Paris"
}

返回如下Passenger记录:

{
   LastName = "Doe"
   Name = "John"
   Trips = [
       { From = "Buenos Aires"; To = "Madrid" }
       { From = "Madrid"; To = "Paris" }
   ]
}

Answer 1

您有什么理由想要使用计算表达式构建器吗？根据您的示例,它看起来不像您正在编写类似计算的任何内容.如果你只是想要一个漂亮的DSL来创建旅行,那么你可以很容易地定义一些让你写的东西:

let p = 
  passenger [
    name "John"
    lastName "Doe"
    trip from "Buenos Aires" towards "Madrid"
    trip from "Madrid" towards "Paris"
  ]

这几乎就是你要求的,除了它使用[ .. ]而不是{ .. }(因为它创建了一个转换列表).我也重命名to为towards因为to是一个关键字,你不能重新定义它.

这个代码很容易编写和遵循:

let passenger ops = 
  ops |> List.fold (fun ps op -> op ps)
    { Name = ""; LastName = ""; Trips = [] } 

let trip op1 arg1 op2 arg2 ps = 
  let trip = 
    [op1 arg1; op2 arg2] |> List.fold (fun tr op -> op tr)
      { From = ""; To = "" }
  { ps with Trips = trip :: ps.Trips }

let name n ps = { ps with Name = n }
let lastName n ps = { ps with LastName = n }
let from n tp = { tp with From = n }
let towards n tp = { tp with To = n }

也就是说,我仍然会考虑使用普通的F#记录语法 - 它没有那么多丑陋.上述版本的一个缺点是你可以用空名和姓名创建乘客,这是F#阻止你的一件事!