将值从C程序传递到汇编语言

Question

我想使用链接汇编方法而不是C中的内联汇编方法将值从C程序传递到汇编.下面是正在处理的汇编程序(GCD).

;gcdasm.nasm
bits 64
section .text
global gcdasm
gcdasm:
    push rbp
    mov rbp, rsp
    mov rax, [rbp+4]        ;load rax with x
    mov rbx, [rbp+8]        ;load rbx with y
top:
    cmp rax, rbx            ;x(rax) has to be larger than y(rbx)
    je exit                 ;if x=y then exit and return value y
    jb xchange              ;if x<y then swap x and y
modulo:
    cqo                     ;RDX:RAX sign extend
    div rbx                 ;div rdx:rax with rbx
    cmp rdx, 0              ;check remider if its 0
    je exit                 ;if reminder is 0 then exit return return y
    mov rax, rdx            ;reminder rdx as next dividend
    jmp modulo              ;loop 
xchange:
    xchg rax, rbx           ;swap x and y
    jmp modulo

exit:
    mov rax, rbx            ;Return c program with the divisor y
    mov rsp, rbp
    pop rbp
    ret

这是我正在尝试将值传递给汇编程序的C程序

//gcd.c
#include<stdio.h>

extern int gcdasm(int x, int y); 

int main(void){
    int x=0;
    int y=0;
    int result=0;

    x = 46; 
    y = 90; 
    printf("%d and %d have a gcd of %d\n", x,y,gcdasm(x,y));

    x = 55;
    y = 66;
    printf("%d and %d have a gcd of %d\n", x,y,gcdasm(x,y));

    return 0;
}

当我使用下面的方法编译并运行它.我得到错误Floating point exception或空提示等待输入

$ nasm -felf64 gcdasm.nasm -o gcdasm.o
$ gcc gcdasm.o gcd.c -o gcd
$ ./gcd 
Floating point exception
$ ./gcd 

我无法弄清楚错误.请帮助我.谢谢.

Answer 1

将参数传递给gcdasm()

这两个int参数通过寄存器传递，而不是堆栈。rdi第一个和第二个参数分别在和的下半部分传递rsi（即：edi和esi）。因此，通过分别将edi和符号扩展esi为rax和rbx，将传递的参数加载到这些寄存器中：

movsx rax, edi  ;load rax with x
movsx rbx, esi  ;load rbx with y

但是，请注意，这rbx不是暂存寄存器，因此被调用者需要在修改它之前保存它，然后在离开函数之前将其恢复回来gcdasm。

您可以简单地在代码中的任何地方替换rbx为rcx（这不是被调用者保存的寄存器）。您根本不需要rbp，因此您可以删除出现的所有说明rbp。

其他问题

• 程序逻辑也有问题：

  mov rax, rdx   ;reminder rdx as next dividend
  

  相反，除数( rcx) 应变为被除数( rax)，余数( rdx) 应变为除数( rcx)，即：

  mov rax, rcx
  mov rcx, rdx
  

• 当除以有符号值时，必须使用idiv指令，而不是div。

改进

还有一些关于性能和代码大小的原因，test rdx, rdx而不是与零cmp rdx, 0进行比较rdx。

考虑到上述所有内容：

;gcdasm.nasm
bits 64
section .text
global gcdasm
gcdasm:
    movsx rax, edi          ;load rax with x
    movsx rcx, esi          ;load rcx with y
top:
    cmp rax, rcx            ;x(rax) has to be larger than y(rcx)
    je exit                 ;if x=y then exit and return value y
    jb xchange              ;if x<y then swap x and y
modulo:
    cqo                     ;sign extend RDX:RAX
    idiv rcx                ;rdx:rax/rcx (signed values)
    test rdx, rdx           ;check whether remainder is zero
    je exit                 ;if reminder is 0 then exit return y
    mov rax, rcx            ;divisor becomes dividend
    mov rcx, rdx            ;remainder becomes divisor
    jmp modulo              ;loop 
xchange:
    xchg rax, rcx           ;swap x and y
    jmp modulo

exit:
    mov rax, rcx            ;Return c program with the divisor y
    ret