使用awk将列转换为矩阵格式

Question

我有一个列格式的网格数据文件:

ifile.txt
x     y     value
20.5  20.5  -4.1
21.5  20.5  -6.2
22.5  20.5   0.0
20.5  21.5   1.2
21.5  21.5   4.3
22.5  21.5   6.0
20.5  22.5   7.0
21.5  22.5  10.4
22.5  22.5  16.7

我想将其转换为矩阵格式为:

ofile.txt
     20.5  21.5 22.5
20.5 -4.1   1.2  7.0
21.5 -6.2   4.3 10.4
22.5  0.0   6.0 16.7

top 20.5 21.5 22.5表示y,side值表示x,内部值表示相应的网格值.

我在这里找到了一个类似的问题将3列文件转换为矩阵格式,但脚本在我的情况下不起作用.

脚本是

awk '{ h[$1,$2] = h[$2,$1] = $3 }
    END {
      for(i=1; i<=$1; i++) {
        for(j=1; j<=$2; j++)
          printf h[i,j] OFS
        printf "\n"
      }
    }' ifile

Answer 1

以下awk脚本处理:

• 任何大小的矩阵
• 行和列索引之间没有关系,因此它会分别跟踪它们.
• 如果未显示某个行列索引,则该值将默认为零.

这是通过这种方式完成的:

awk '
BEGIN{PROCINFO["sorted_in"] = "@ind_num_asc"}
(NR==1){next}
{row[$1]=1;col[$2]=1;val[$1" "$2]=$3}
END { printf "%8s",""; for (j in col) { printf "%8.3f",j }; printf "\n"
      for (i in row) {
        printf "%8.3f",i; for (j in col) { printf "%8.3f",val[i" "j] }; printf "\n"
      }
    }' <file>

它是如何工作的:

• PROCINFO["sorted_in"] = "@ind_num_asc",声明所有数组都按索引进行数字排序.
• (NR==1){next} :跳过第一行
• {row[$1]=1;col[$2]=1;val[$1" "$2]=$3},通过存储行和列索引以及伴随值来处理该行.
• 结束语句完成所有打印.

这输出:

          20.500  21.500  22.500
  20.500  -4.100   1.200   7.000
  21.500  -6.200   4.300  10.400
  22.500   0.000   6.000  16.700

注意:使用PROCINFO是一个gawk功能.

但是,如果你做了几个假设,你可以做得更短:

• 该文件包含所有可能的条目,没有缺失值
• 你不希望打印出行和列的索引:
• 索引按列主顺序排序

您可以使用以下简短版本:

sort -g <file> | awk '($1+0!=$1){next}
                      ($1!=o)&&(NR!=1){printf "\n"}
                      {printf "%8.3f",$3; o=$1 }'

哪个输出

  -4.100   1.200   7.000
  -6.200   4.300  10.400
   0.000   6.000  16.700

或换位:

awk '(NR==1){next}
     ($2!=o)&&(NR!=2){printf "\n"}
     {printf "%8.3f",$3; o=$2 }' <file>

这输出

  -4.100  -6.200   0.000
   1.200   4.300   6.000
   7.000  10.400  16.700