Delphi中的XML命名空间

Question

我试图访问我的XML文件中的一些节点,但我不能让它工作,因为我可能不理解Delphi中的XML-Namepsaces.

<gesmes:Envelope xmlns:gesmes="http://www.gesmes.org/xml/2002-08-01" xmlns="http://www.ecb.int/vocabulary/2002-08-01/eurofxref">
    <gesmes:subject>Reference rates</gesmes:subject>
    <gesmes:Sender>
        <gesmes:name>European Central Bank</gesmes:name>
    </gesmes:Sender>
    <Cube>
        <Cube time="2018-01-18">
            <Cube currency="USD" rate="1.2235"/>
            <Cube currency="JPY" rate="136.07"/>
            <Cube currency="BGN" rate="1.9558"/>
            <Cube currency="CZK" rate="25.365"/>
            <Cube currency="DKK" rate="7.4475"/>
            <Cube currency="GBP" rate="0.88208"/>
            <Cube currency="HUF" rate="308.51"/>
            <Cube currency="PLN" rate="4.1665"/>
            <Cube currency="RON" rate="4.6480"/>
            <Cube currency="SEK" rate="9.8305"/>
            <Cube currency="CHF" rate="1.1748"/>
            <Cube currency="NOK" rate="9.6013"/>
            <Cube currency="HRK" rate="7.4409"/>
            <Cube currency="RUB" rate="69.2126"/>
            <Cube currency="TRY" rate="4.6374"/>
            <Cube currency="AUD" rate="1.5311"/>
            <Cube currency="BRL" rate="3.9321"/>
            <Cube currency="CAD" rate="1.5229"/>
            <Cube currency="CNY" rate="7.8582"/>
            <Cube currency="HKD" rate="9.5648"/>
            <Cube currency="IDR" rate="16325.38"/>
            <Cube currency="ILS" rate="4.1950"/>
            <Cube currency="INR" rate="78.1210"/>
            <Cube currency="KRW" rate="1306.61"/>
            <Cube currency="MXN" rate="22.8174"/>
            <Cube currency="MYR" rate="4.8396"/>
            <Cube currency="NZD" rate="1.6759"/>
            <Cube currency="PHP" rate="62.068"/>
            <Cube currency="SGD" rate="1.6175"/>
            <Cube currency="THB" rate="39.054"/>
            <Cube currency="ZAR" rate="15.0035"/>
        </Cube>
    </Cube>
</gesmes:Envelope>

我试图像这样访问多维数据集节点:

procedure TForm2.Button1Click(Sender: TObject);
var
  Doc: IXMLDocument;
  Node: IXMLNode;
  sl: TStringList;
begin
  Doc := LoadXMLDocument('C:\Users\Kevin\Desktop\test.xml');
  node := Doc.DocumentElement;

  ShowMessage(Node.ChildNodes['Cube']);
end;

我意识到我的输出是:"gesmes:Cube".我不认为这是对的...我想要获得第一个"立方体"节点.我不确定Delphi中的命名空间是如何工作的,所以如果我能在这里获得一些帮助会很棒.

最好的祝福!

Answer 1

您正在传递一个IXMLNode接口指针ShowMessage(),而这需要string改为.所以,在您的真实代码中,您实际上已经完成了ShowMessage(Node.ChildNodes['Cube'].NodeName);.

确实有报道'gesmes:Cube',这不是你所期待的.在Cube你想要的是在http://www.ecb.int/vocabulary/2002-08-01/eurofxref命名空间,这比其母公司的名称空间不同的Envelope(http://www.gesmes.org/xml/2002-08-01).所以实际发生的是DocumentElement.ChildNodes['Cube']尝试Cube在Envelope命名空间中找到一个,找不到这样的元素,因此TXMLDocument 创建一个新元素,因为doNodeAutoCreate该Doc.Options属性默认启用了该标志.这是Cube该DocumentElement.ChildNodes['Cube']返回,而不是Cube你想要的.

因为它Envelope和它的直接Cube子节点在不同的命名空间中,你不能使用ChildNodes['Cube']它DocumentElement,你必须使用,ChildNodes.FindNode()而是指定Cube实际的命名空间:

Node := Doc.DocumentElement;
Node := Node.ChildNodes.FindNode('Cube', 'http://www.ecb.int/vocabulary/2002-08-01/eurofxref');

下一个Cube与其父级在同一名称空间中Cube,因此您可以使用ChildNodes['Cube']它来获取它:

Node := Node.ChildNodes['Cube'];

然后time,如果需要,您可以访问该属性:

Node.Attributes['time']

并循环通过剩下的孩子Cube:

Node := Node.ChildNodes.First;
while Node <> nil do
begin
  if Node.LocalName = 'Cube' then
  begin
    // use Node.Attributes['currency'] and Node.Attributes['rate'] as needed...
  end;
  Node := Node.NextSibling;
end;

这是完整的代码:

procedure TForm2.Button1Click(Sender: TObject);
var
  Doc: IXMLDocument;
  Node: IXMLNode;
  sl: TStringList;
begin
  sl := TStringList.Create;
  try
    Doc := LoadXMLDocument('C:\Users\Kevin\Desktop\test.xml');
    try
      Node := Doc.DocumentElement;
      if Node = nil then ... // handle the error as needed...

      Node := Node.ChildNodes.FindNode('Cube', 'http://www.ecb.int/vocabulary/2002-08-01/eurofxref');
      if Node = nil then ... // handle the error as needed...

      Node := Node.ChildNodes['Cube'];
      if Node = nil then ... // handle the error as needed...

      Node := Node.ChildNodes.First;
      while Node <> nil do
      begin
        if Node.LocalName = 'Cube' then
          sl.Add(Node.Attributes['currency'] + '=' + Node.Attributes['rate']);
        Node := Node.NextSibling;
      end;
    finally
      Node := nil;
      Doc := nil;
    end;

    // use sl as needed...

  finally
    sl.Free;
  end;
end;