如何使用XSLT将XML文件拆分为多个XML文件

Question

我想知道如何根据这些要求编写XSLT将XML文件拆分为多个XML文件:

• file1.xml - 键入= Natyral的湖泊
• file2.xml - 键入= Artificial的湖泊
• file3.xml - 键入= Glacial的湖泊

XML imput文件是:

<Lakes>
  <Lake>
    <id>1</id>
    <Name>Caspian</Name>
    <Type>Natyral</Type>
  </Lake>
  <Lake>
    <id>2</id>
    <Name>Moreo</Name>
    <Type>Glacial</Type>
  </Lake>
  <Lake>
    <id>3</id>
    <Name>Sina</Name>
    <Type>Artificial</Type>
  </Lake>
</Lakes>

Answer 1

使用XSLT 2.0,就像这个样式表:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <xsl:for-each-group select="Lakes/Lake" group-by="Type">
            <xsl:result-document href="file{position()}.xml">
                <Lakes>
                    <xsl:copy-of select="current-group()"/>
                </Lakes>
            </xsl:result-document>
        </xsl:for-each-group>
    </xsl:template>
</xsl:stylesheet>

注意:xsl:result-document说明.

Answer 2

对于标准 XSL，不可能有多个输出 xml（即生成的树）。
但是，使用 Xalan重定向扩展就可以。

查看链接中页面上的示例。我使用 Xalan Java 2.7.1 测试了以下内容

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:redirect="http://xml.apache.org/xalan/redirect" extension-element-prefixes="redirect">

    <xsl:output method="xml" indent="yes" />

    <xsl:template match="/">
        <xsl:apply-templates />
    </xsl:template>

    <xsl:template match="/Lakes/Lake[Type='Natyral']">
        <redirect:write file="/home/me/file1.xml">
            <NatyralLakes>
                <xsl:copy-of select="." />
            </NatyralLakes>
        </redirect:write>
    </xsl:template>

    <xsl:template match="/Lakes/Lake[Type='Artificial']">
        <redirect:write file="/home/me/file1.xml">
            <ArtificialLakes>
                <xsl:copy-of select="." />
            </ArtificialLakes>
        </redirect:write>
    </xsl:template>

    <xsl:template match="/Lakes/Lake[Type='Glacial']">
        <redirect:write file="/home/me/file3.xml">
            <GlacialLakes>
                <xsl:copy-of select="." />
            </GlacialLakes>
        </redirect:write>
    </xsl:template>


</xsl:stylesheet>