Spock Stub的泛型

Question

我无法为泛型类编译Spock存根.构造函数的签名如下:

SomeClass(SerSup<Cap> capSup, String foo, String bar);

我需要存根第一个参数.以下是我失败的尝试.

第一次尝试:

def someClass = new SomeClass(Stub(SerSup<Cap>), "foo", "bar")

Error: Groovyc: unexpected token: >
Status bar: ',' or ')' expected

另一个尝试:

def someClass = new someClass(Stub(Cup) as SerSup<Cup>, "foo" ,"bar")

groovy.lang.MissingMethodException: No signature of method: com.sun.proxy.$Proxy10.get() is applicable for argument types: () values: []
Possible solutions: grep(), getAt(java.lang.String), grep(java.lang.Object), wait(), any(), wait(long)

at loom.SomeClass.SomeMethod(SomeClassTest.groovy:14)

存根SomeClass构造函数的第一个参数的正确方法是什么？

Answer 1

你的第二个尝试失败,因为你可以不投Stup(Cap)给SerSup<Cap>.您必须Stub(SerSup)改为,或者您可以应用我在下面描述的建议.

我建议在初始化之前为存根创建一个变量SomeClass.您可以使用Stub(type: ...)构造函数来存储泛型类,例如

SerSup<String> serSup = Stub(type: new TypeToken<SerSup<String>>(){}.type) as SerSup<String>

此初始化不会在IDE中产生任何警告.如果您对某些警告没问题,可以将其简化为:

def serSup = Stub(type: new TypeToken<SerSup<String>>(){}.type)

或者你可以尝试类似的东西:

SerSup<String> serSup = Stub(SerSup) {
    get() >> ""
}

这个替代解决方案需要使用stubbing方法返回有效类型,否则返回等效的new Object().在第一种情况下,返回"default"值,因为我们满足所有类型检查(例如,在String返回空字符串的情况下).

这是一个显示两种方法的示例:

import com.google.common.reflect.TypeToken
import spock.lang.Specification

class StubSpec extends Specification {

    def "test stubbing with default value for String"() {
        when:
        SerSup<String> serSup = Stub(type: new TypeToken<SerSup<String>>(){}.type) as SerSup<String>


        then:
        serSup.get() == ""
    }

    def "test stubbing without explicit type"() {
        when:
        SerSup<String> serSup = Stub(SerSup) {
            get() >> "lorem ipsum"
        }

        then:
        serSup.get() == "lorem ipsum"
    }

    static class SerSup<T> {
        private final T obj

        SerSup(T t) {
            this.obj = t
        }

        T get() {
            return obj
        }
    }
}