使用 GHC.Generics 将数据构造函数名称作为字符串获取

Question

我想要类似以下内容：

constrName :: Data a=> a -> String
constrName = showConstr . toConstr

但是对于GHC.Generics. 我看到了这个Constructor类，但在范围内没有看到任何实例。我正在使用base-4.8.1.0.

Answer 1

改编 Nathan Howell 的这个要点：https : //gist.github.com/NathanHowell/6201625 ：

{-# LANGUAGE DeriveGeneric #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE KindSignatures #-}
{-# LANGUAGE TypeSynonymInstances #-}
{-# LANGUAGE TypeOperators #-}
{-# LANGUAGE FlexibleContexts #-}

import GHC.Generics

constrName :: (HasConstructor (Rep a), Generic a)=> a -> String
constrName = genericConstrName . from 

class HasConstructor (f :: * -> *) where
  genericConstrName :: f x -> String

instance HasConstructor f => HasConstructor (D1 c f) where
  genericConstrName (M1 x) = genericConstrName x

instance (HasConstructor x, HasConstructor y) => HasConstructor (x :+: y) where
  genericConstrName (L1 l) = genericConstrName l
  genericConstrName (R1 r) = genericConstrName r

instance Constructor c => HasConstructor (C1 c f) where
  genericConstrName x = conName x

--------------
data Foo = Bar Int | Baz Float deriving Generic
newtype X = X Char deriving Generic
data Y = Y deriving Generic

我们可以做的：

*Main> constrName (Bar 1)
"Bar"
*Main> constrName $ X 'a'
"X"
*Main> constrName Y
"Y"