在 Debian 上的 CMake 中查找 GeographicLib

Question

在 Debian 上，我已经安装了 cmake 和 geoliblib，如下所示：

stew@stewbian:~$apt-get install build-essential cmake libgeographic-dev

我的 CMakeLists.txt 文件如下所示：

cmake_minimum_required(VERSION 3.7)
project(geoexample)

find_package(GeographicLib REQUIRED)

add_executable(geoexample main.cpp)

target_include_directories(geoexample PRIVATE ${GeographicLib_INCLUDE_DIRS})
target_compile_definitions(geoexample PRIVATE ${GeographicLib_DEFINITIONS})
target_link_libraries     (geoexample         ${GeographicLib_LIBRARIES})

我的main.cpp也很简单（直接取自示例）：

#include <iostream>
#include <GeographicLib/Geodesic.hpp>
using namespace std;
using namespace GeographicLib;
int main() {
    const Geodesic& geod = Geodesic::WGS84();
    // Distance from JFK to LHR
    double
      lat1 = 40.6, lon1 = -73.8, // JFK Airport
      lat2 = 51.6, lon2 = -0.5;  // LHR Airport
    double s12;
    geod.Inverse(lat1, lon1, lat2, lon2, s12);
    cout << s12 / 1000 << " km\n";
    return 0;
}

当我跑步时mkdir build && cd build && cmake ..我得到

stew@stewbian:~/src/geoexample/build$ cmake ..
CMake Error at CMakeLists.txt:3 (find_package):
  By not providing "FindGeographicLib.cmake" in CMAKE_MODULE_PATH this
  project has asked CMake to find a package configuration file provided by
  "GeographicLib", but CMake did not find one.

我认为默认情况下，cmake 搜索/usr/share/cmake-3.7/Modules，但 libgeographic-dev 似乎已将其 Find*.cmake 安装到/usr/share/cmake/geographiclib/FindGeographicLib.cmake。这很令人沮丧，但我自己（加上每个需要编译我的代码的人）应该能够对这个简单的情况使用解决方法（如果我还需要包含像 FindBoost.cmake 这样的东西，它就不会那么好用）旧位置）。

stew@stewbian:~/src/geoexample/build$ cmake .. -DCMAKE_MODULE_PATH=/usr/share/cmake/geographiclib
CMake Error at /usr/share/cmake-3.7/Modules/FindPackageHandleStandardArgs.cmake:138 (message):
  Could NOT find GeographicLib (missing: GeographicLib_LIBRARY_DIRS
  GeographicLib_INCLUDE_DIRS)
Call Stack (most recent call first):
  /usr/share/cmake-3.7/Modules/FindPackageHandleStandardArgs.cmake:378 (_FPHSA_FAILURE_MESSAGE)
  /usr/share/cmake/geographiclib/FindGeographicLib.cmake:28 (find_package_handle_standard_args)
  CMakeLists.txt:4 (find_package)


-- Configuring incomplete, errors occurred!

现在我不知道在这里做什么。我可以确认 libgeographic-dev 软件包已安装/usr/lib/x86_64-linux-gnu/libGeographic.a并且/usr/lib/x86_64-linux-gnu/libGeographic.so

Answer 1

下游项目的解决方法：添加

set(CMAKE_MODULE_PATH "${CMAKE_MODULE_PATH};/usr/share/cmake/geographiclib")

就在之前find_package(GeographicLib REQUIRED)。这修复了损坏的 Debian/Ubuntu 安装程序。其他发行版可能会将文件放在其他地方，但......

Answer 2

根据此错误报告，

geographylib-dev 安装程序将 FindGeographicLib.cmake 文件放入： /usr/share/cmake/geographiclib/FindGeographicLib.cmake

正确的位置是：/usr/share/cmake-3.5/Modules

事实上，这取决于当前安装的 cmake 版本。在 Ubuntu 18.04 中，它是 3-10。

所以你可以这样解决这个问题：

sudo ln -s /usr/share/cmake/geographiclib/FindGeographicLib.cmake /usr/share/cmake-3.10/Modules/

Answer 3

我编写了自己的 FindGeographicLib.cmake 来查找它并将其安装在我的项目的子文件夹中。然后我${CMAKE_MODULES_PATH}在我的项目中指向这个文件夹CMakeLists.txt：

list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/modules)

我首先添加了 libgeographic-dev 部署的：

cp /usr/share/cmake/geographiclib/FindGeographicLib.cmake ./modules/FindGeographicLib.cmake

不幸的是，这并不能开箱即用。该库位于 处，并且脚本没有很好地处理/usr/lib/x86_64-linux-gnu/libGeographic.so额外的内容。x86_64-linux-gnu它尝试（但失败了）在/usr/lib/include. 我对脚本做了一些调整来检查这种情况，现在我有了一个可行的解决方案。

新的FindGeographicLib.cmake如下所示。我的更改以适用行右侧的注释表示。

# Look for GeographicLib
#
# Sets
#  GeographicLib_FOUND = TRUE
#  GeographicLib_INCLUDE_DIRS = /usr/local/include
#  GeographicLib_LIBRARIES = /usr/local/lib/libGeographic.so
#  GeographicLib_LIBRARY_DIRS = /usr/local/lib

find_library (GeographicLib_LIBRARIES Geographic
  PATHS "${CMAKE_INSTALL_PREFIX}/../GeographicLib/lib")

  if (GeographicLib_LIBRARIES)
  get_filename_component (GeographicLib_LIBRARY_DIRS
    "${GeographicLib_LIBRARIES}" PATH)

  get_filename_component (_ROOT_DIR "${GeographicLib_LIBRARY_DIRS}" PATH)
  set (GeographicLib_INCLUDE_DIRS "${_ROOT_DIR}/include")
  set (GeographicLib_BINARY_DIRS "${_ROOT_DIR}/bin")
  if (NOT EXISTS "${GeographicLib_INCLUDE_DIRS}/GeographicLib/Config.h")
    get_filename_component(_ROOT_DIR "${_ROOT_DIR}" PATH)                     # Added to script
    set (GeographicLib_INCLUDE_DIRS "${_ROOT_DIR}/include")                   # Added to script
    set (GeographicLib_BINARY_DIRS "${_ROOT_DIR}/bin")                        # Added to script
    if (NOT EXISTS "${GeographicLib_INCLUDE_DIRS}/GeographicLib/Config.h")    # Added to script
      unset (GeographicLib_INCLUDE_DIRS)
      unset (GeographicLib_LIBRARIES)
      unset (GeographicLib_LIBRARY_DIRS)
      unset (GeographicLib_BINARY_DIRS)
    endif()                                                                   # Added to script
  endif ()
  unset (_ROOT_DIR)                                                           # Moved below if() statements
endif ()

include (FindPackageHandleStandardArgs)
find_package_handle_standard_args (GeographicLib DEFAULT_MSG
  GeographicLib_LIBRARY_DIRS GeographicLib_LIBRARIES GeographicLib_INCLUDE_DIRS)
mark_as_advanced (GeographicLib_LIBRARY_DIRS GeographicLib_LIBRARIES
  GeographicLib_INCLUDE_DIRS)

编辑（2024）：

Debian Bookworm 已经发布一段时间了，该版本的 Debian 从 更名为libgeographicGeographicLib libGeographicLib。NAMES但我们仍然可以通过使用以下部分来获得适用于两个版本的脚本find_library()

# Look for GeographicLib
#
# Sets
#  GeographicLib_FOUND = TRUE
#  GeographicLib_INCLUDE_DIRS = /usr/local/include
#  GeographicLib_LIBRARIES = /usr/local/lib/libGeographic.so
#  GeographicLib_LIBRARY_DIRS = /usr/local/lib

find_library (GeographicLib_LIBRARIES
  NAMES Geographic GeographicLib
  PATHS "${CMAKE_INSTALL_PREFIX}/../GeographicLib/lib")

  if (GeographicLib_LIBRARIES)
  get_filename_component (GeographicLib_LIBRARY_DIRS
    "${GeographicLib_LIBRARIES}" PATH)

  get_filename_component (_ROOT_DIR "${GeographicLib_LIBRARY_DIRS}" PATH)
  set (GeographicLib_INCLUDE_DIRS "${_ROOT_DIR}/include")
  set (GeographicLib_BINARY_DIRS "${_ROOT_DIR}/bin")
  if (NOT EXISTS "${GeographicLib_INCLUDE_DIRS}/GeographicLib/Config.h")
    get_filename_component(_ROOT_DIR "${_ROOT_DIR}" PATH)
    set (GeographicLib_INCLUDE_DIRS "${_ROOT_DIR}/include")
    set (GeographicLib_BINARY_DIRS "${_ROOT_DIR}/bin")
    if (NOT EXISTS "${GeographicLib_INCLUDE_DIRS}/GeographicLib/Config.h")
      unset (GeographicLib_INCLUDE_DIRS)
      unset (GeographicLib_LIBRARIES)
      unset (GeographicLib_LIBRARY_DIRS)
      unset (GeographicLib_BINARY_DIRS)
    endif()
  endif ()
  unset (_ROOT_DIR)
endif ()

include (FindPackageHandleStandardArgs)
find_package_handle_standard_args (GeographicLib DEFAULT_MSG
  GeographicLib_LIBRARY_DIRS GeographicLib_LIBRARIES GeographicLib_INCLUDE_DIRS)
mark_as_advanced (GeographicLib_LIBRARY_DIRS GeographicLib_LIBRARIES
  GeographicLib_INCLUDE_DIRS)