EXCEL 64位命令行vba代码

Question

我有在打开 excel 书时获取命令行参数的代码（64 位；但 32 位代码也存在于 #if 子句下）。

例如，当我在命令提示符下运行以下代码行时，我希望能够获取输入字符串作为命令行参数：

启动 Excel ".\AwajiPush.xlsm" /p/"kjh%dg.pdf"

（顺便说一句，“开始”之所以在那里，是为了它可以在 .bat 批处理文件中工作）

我希望能够捕获 ".\AwajiPush.xlsm" 和 /p/"kjh%dg.pdf" 作为参数。

代码不会那样做。

为什么不获取第二个参数？

我不太了解指针的工作原理。是否有一段代码可以用来捕获至少一个包含两个参数的字符串，以便我可以解析它。如果它包含更多，那很好。我总是可以解释它，只要它是一致的。

我将存根放入程序 (MsgBox) 中，但我不确定为什么第二个存根显示为空白。

这是代码：

'Put this code in a new module called Parameters

Option Explicit

#If Win64 Then
    Private Declare PtrSafe Function GetCommandLineL Lib "kernel32" _
     Alias "GetCommandLineA" () As LongPtr

    Private Declare PtrSafe Function lstrcpyL Lib "kernel32" _
     Alias "lstrcpyA" (ByVal lpString1 As String, ByVal lpString2 As LongPtr) As Long

    Private Declare PtrSafe Function lstrlenL Lib "kernel32" _
     Alias "lstrlenA" (ByVal lpString As LongPtr) As Long


 #Else
    Private Declare Function GetCommandLineL Lib "kernel32" _
     Alias "GetCommandLineA" () As Long

    Private Declare Function lstrcpyL Lib "kernel32" _
     Alias "lstrcpyA" (ByVal lpString1 As String, ByVal lpString2 As Long) As Long

    Private Declare Function lstrlenL Lib "kernel32" _
     Alias "lstrlenA" (ByVal lpString As Long) As Long

 #End If

 Function GetCommandLine() As String
   Dim strReturn As String
   #If Win64 Then
   Dim lngPtr As LongPtr
   #Else
   Dim lngPtr As Long
   #End If

   Dim StringLength As Long
   'Get the pointer to the commandline string
   lngPtr = GetCommandLineL

   'get the length of the string (not including the terminating null character):
   StringLength = lstrlenL(lngPtr)
   MsgBox StringLength


   'initialize our string so it has enough characters including the null character:
   strReturn = String$(StringLength + 1, 0)
   'copy the string we have a pointer to into our new string:
   MsgBox strReturn


   lstrcpyL strReturn, lngPtr
   'now strip off the null character at the end:
   MsgBox strReturn


   GetCommandLine = Left$(strReturn, StringLength)

 End Function

和

'Put this code in "This Workbook"

Sub workBook_open()
    MsgBox Parameters.GetCommandLine
End Sub

Answer 1

这是一个从当前进程获取命令行的函数：

Private Declare PtrSafe Function w_commandline Lib "kernel32.dll" Alias "GetCommandLineW" () As LongPtr
Private Declare PtrSafe Function w_strlen Lib "kernel32.dll" Alias "lstrlenW" (ByVal lpString As LongPtr) As Long
Private Declare PtrSafe Sub w_memcpy Lib "kernel32.dll" Alias "RtlMoveMemory" (dst As Any, src As Any, ByVal size As LongPtr)

Public Function GetCommandLine() As String
  GetCommandLine = String$(w_strlen(w_commandline()), 0)
  w_memcpy ByVal StrPtr(GetCommandLine), ByVal w_commandline(), LenB(GetCommandLine)
End Function

Sub Test()
  Debug.Print GetCommandLine()
End Sub

请注意，您必须使用/e开关来避免重定向到已启动的 Excel 实例，从而保留提供的参数。例如：

excel.exe /e "C:\temp\myfile.xlsm" /p "myparam"

或与start：

start "xl" excel.exe /e "C:\temp\myfile.xlsm" /p "myparam"

但是，如果您的目标是从批处理中向 VBA 提供一些参数，请使用环境变量：

Set MyArguments=abcde
start "xl" excel.exe /e "C:\temp\myfile.xlsm"

，然后从 Excel 获取参数：

Debug.Print Environ("MyArguments") ' >> "abcde" '