从异步方法访问logger对象时的死锁同步运行

Question

下面的代码试图做一些工作,如果有错误则重试.还有一个错误回调,它调用一个将错误记录到控制台的函数.

执行时,错误仅记录到控制台一次,当程序暂停时,主线程被阻塞,retryErrorForever工作线程被阻塞log.

但为什么？

module Program

type MyLogger(loggerName: string) =
    member __.Warn fmt =
        Printf.kprintf (printfn "%s: %s" loggerName) fmt

let log = MyLogger("Logger")

let retryErrorForever errorCallback retryTimeout work =
    let rec loop () = async {
        let! result = work

        match result with
        | Error e ->
            errorCallback e
            do! Async.Sleep retryTimeout
            return! loop()
        | Ok x -> return Ok x
    }

    loop ()

let retryWorkUntilOk logError timeout (work: unit -> Result<string, string>) =
    let workflow = async {
        return work ()
    }

    let result =
        retryErrorForever logError timeout workflow
        |> Async.RunSynchronously

    match result with
    | Ok x -> x
    | Error e -> failwith <| sprintf "Cannot doWork: %s" e

let logError error =
    log.Warn "%s" error

let doWork work =
    retryWorkUntilOk logError 1000 work

let errorOnly () : Result<string, string> =
    Error "You have no power here"

let result = doWork errorOnly

[<EntryPoint>]
let main _ =
    printfn "%A" result
    0

Answer 1

当以交互方式运行时,这个程序完全按照预期的方式执行:每秒打印"你没有力量".

但是如果你正在编译它并运行可执行文件,那就有一个问题:let result = ...在程序集初始化之前main,甚至在运行之前评估行,并在此期间执行整个程序内容.但是,程序集初始化应该是同步的.它可以启动异步任务,但是在静态初始化完成之前它们将无法完成 - 以及编写程序的方式,静态初始化正在等待那些异步任务完成.所以你陷入了僵局.

要解决这个问题,只需在整个main过程中运行,而不是在静态初始化期间运行.这可以通过创建result一个函数然后从main以下方法调用它来完成:

let result() = doWork errorOnly

[<EntryPoint>]
let main _ =
    printfn "%A" <| result()
    0