Elixir：__ using __ / 1是未定义的或私有的

Question

我正在使用Elixir + Phoenix 1.3并定义了Accounts上下文。我想将accounts.ex文件用作其他模块中要求的索引，以防止它变得太大，但我无法从我创建的其他模块中导入功能。

我的文件结构如下：

lib
|- Project
  |- Accounts
    |- accounts.ex
    |- user_api.ex

这是我的accounts.ex文件的外观：

# accounts.ex

defmodule Project.Accounts do
  @moduledoc """
  The Accounts context.
  """
  import Ev2Web
  import Ecto.Query, warn: false
  alias Project.{Accounts}

  use Accounts.UserAPI


end

这是我要导入的模块：

# user_api.ex

defmodule Project.Accounts.UserAPI do

  alias Project.{Repo}
  alias Project.{Accounts.User}

  def list_users do
    Repo.all(User)
  end
end

我希望能够导入我的Project.Accounts.UserAPI模块，以便可以Project.Accounts.list_users()在我的控制器中进行引用，但是未导入这些模块。我得到了错误function Project.Accounts.UserAPI.__using__/1 is undefined or private。

我的控制器如下所示：

defmodule ProjectWeb.UserController do
  use ProjectWeb, :controller

  alias Project.Accounts

  def index(conn, _params) do
    users = Accounts.list_users()
    render(conn, "index.html", users: users)
  end
end

有谁知道如何将所有功能从一个模块导入另一个模块，以便可以使用？提前致谢！

Answer 1

您必须包含__using__宏并将所有应编译到 using 模块中的代码放在那里。像这样：

defmodule Project.Accounts.UserAPI do

  defmacro __using__(_) do
    quote do
      alias Project.{Repo}
      alias Project.{Accounts.User}

      def list_users do
        Repo.all(User)
      end
    end
  end
end