获取从注入到"nat"的类型的可判定总订单

Question

由于自然数支持可判定的总订单,因此注入nat_of_ascii (a : ascii) : nat会在类型上产生可判定的总订单ascii.在Coq中表达这一点的简洁,惯用的方式是什么？(有或没有类型类,模块等)

Answer 1

这样的过程是相当常规的,取决于您选择的库.对于order.v,基于math-comp,这个过程是完全机械的[事实上,我们将为后期在后期注入总订单的类型开发一般构造]:

From Coq Require Import Ascii String ssreflect ssrfun ssrbool.
From mathcomp Require Import eqtype choice ssrnat.
Require Import order.

Import Order.Syntax.
Import Order.Theory.

Lemma ascii_of_natK : cancel nat_of_ascii ascii_of_nat.
Proof. exact: ascii_nat_embedding. Qed.

(* Declares ascii to be a member of the eq class *)
Definition ascii_eqMixin := CanEqMixin ascii_of_natK.
Canonical ascii_eqType := EqType _ ascii_eqMixin.

(* Declares ascii to be a member of the choice class *)
Definition ascii_choiceMixin := CanChoiceMixin ascii_of_natK.
Canonical ascii_choiceType := ChoiceType _ ascii_choiceMixin.

(* Specific stuff for the order library *)
Definition ascii_display : unit. Proof. exact: tt. Qed.

Open Scope order_scope.

(* We use the order from nat *)
Definition lea x y := nat_of_ascii x <= nat_of_ascii y.
Definition lta x y := ~~ (lea y x).

Lemma lea_ltNeq x y : lta x y = (x != y) && (lea x y).
Proof.
rewrite /lta /lea leNgt negbK lt_neqAle.
by rewrite (inj_eq (can_inj ascii_of_natK)).
Qed.
Lemma lea_refl : reflexive lea.
Proof. by move=> x; apply: le_refl. Qed.
Lemma lea_trans : transitive lea.
Proof. by move=> x y z; apply: le_trans. Qed.
Lemma lea_anti : antisymmetric lea.
Proof. by move=> x y /le_anti /(can_inj ascii_of_natK). Qed.
Lemma lea_total : total lea.
Proof. by move=> x y; apply: le_total. Qed.

(* We can now declare ascii to belong to the order class. We must declare its
   subclasses first. *)
Definition asciiPOrderMixin :=
  POrderMixin lea_ltNeq lea_refl lea_anti lea_trans.

Canonical asciiPOrderType  := POrderType ascii_display ascii asciiPOrderMixin.

Definition asciiLatticeMixin := Order.TotalLattice.Mixin lea_total.
Canonical asciiLatticeType := LatticeType ascii asciiLatticeMixin.
Canonical asciiOrderType := OrderType ascii lea_total.

请注意,提供订单实例ascii使我们能够访问总订单的大理论,以及运算符等...但是,总计本身的定义非常简单:

"<= is total" == x <= y || y <= x

其中<=是"可判定的关系",我们当然假设特定类型的相等的可判定性.具体而言,对于任意关系:

Definition total (T: Type) (r : T -> T -> bool) := forall x y, r x y || r y x.

所以,如果T是和秩序,并满足total,你就完成了.

更一般地,您可以定义一个通用原则来使用注入来构建此类型:

Section InjOrder.

Context {display : unit}.
Local Notation orderType := (orderType display).
Variable (T : orderType) (U : eqType) (f : U -> T) (f_inj : injective f).

Open Scope order_scope.

Let le x y := f x <= f y.
Let lt x y := ~~ (f y <= f x).
Lemma CO_le_ltNeq x y: lt x y = (x != y) && (le x y).
Proof. by rewrite /lt /le leNgt negbK lt_neqAle (inj_eq f_inj). Qed.
Lemma CO_le_refl : reflexive le. Proof. by move=> x; apply: le_refl. Qed.
Lemma CO_le_trans : transitive le. Proof. by move=> x y z; apply: le_trans. Qed.
Lemma CO_le_anti : antisymmetric le. Proof. by move=> x y /le_anti /f_inj. Qed.

Definition InjOrderMixin : porderMixin U :=
  POrderMixin CO_le_ltNeq CO_le_refl CO_le_anti CO_le_trans.
End InjOrder.

然后,ascii实例重写如下:

Definition ascii_display : unit. Proof. exact: tt. Qed.
Definition ascii_porderMixin := InjOrderMixin (can_inj ascii_of_natK).
Canonical asciiPOrderType := POrderType ascii_display ascii ascii_porderMixin.

Lemma lea_total : @total ascii (<=%O)%O.
Proof. by move=> x y; apply: le_total. Qed.

Definition asciiLatticeMixin := Order.TotalLattice.Mixin lea_total.
Canonical asciiLatticeType := LatticeType ascii asciiLatticeMixin.
Canonical asciiOrderType := OrderType ascii lea_total.