切片数组的引用

Question

我有以下地图:

my %cps_per_level = (
                     Bronze      =>  [100 , 65  ],
                     Silver      =>  [200 , 125 ],
                     Gold        =>  [400 , 250 ],
                     Platinum    =>  [800 , 500 ],
                     Diamond     =>  [1200, 750 ],
                     Master      =>  [2000, 1200],
                     Grandmaster =>  [3000, 1750],
                );

在我的代码中,我希望获得特定条目的列表的两个值到2个变量.我的第一次尝试是取消引用特定条目的列表,然后应用列表切片并将其分配给我想要的变量,如下所示.这里$level有一张地图的关键字.

my ($cps_before, $cps_after) = $cps_per_level{$level}[0,1];

但这不起作用.$cps_before获取列表的第一个值,但$cps_after什么也得不到.我设法通过写两行来使它工作:

my $cps_before= $cps_per_level{$level}[0];
my $cps_after = $cps_per_level{$level}[1];

我的问题是:为什么片不起作用？我错过了什么？

Answer 1

那不是一个切片.如果你有@array,一个切片看起来像这样:

@array[0, 1, 2]

你写的是相当于这个:

$array[0, 1, 2]

... ,在标量上下文中使用并且相当于$array[2].

事实上,

$cps_per_level{$level}[0,1]

是简写

$cps_per_level{$level}->[0,1]

这是语法糖

${ $cps_per_level{$level} }[0, 1]

这只是意味着

${ $cps_per_level{$level} }[1]

你应该做的是:

@{ $cps_per_level{$level} }[0, 1]

这@意味着您要尝试获取多个元素.

如果你的perl足够新(5.20并且自5.24起不再具有实验性),你也可以使用这样的后缀解除引用形式:

$cps_per_level{$level}->@[0, 1]