Perl中的条件编译

Question

如何使以下代码生效？

use strict;
use warnings;

if ($^O eq 'MSWin32' || $^O eq 'MSWin64') {
    use Win32;    
    Win32::MsgBox("Aloha!", MB_ICONINFORMATION, 'Win32 Msgbox');     
}
else {
    print "Do not know how to do msgbox under UNIX!\n";
}

以上在Windows下运行.但是在UNIX下,由于找不到Win32,因此存在编译错误.用"require"替换"use"会使事情变得更糟 - 代码无法在Windows和UNIX下编译,因为包含MB_ICONINFORMATION的行总是被编译而"MB_ICONINFORMATION"将是未声明的单词.

那么我该如何解决这个问题呢？

Answer 1

Perl首先将代码编译为中间表示,然后执行它.由于if在运行时评估但use在编译期间处理,因此您不会有条件地导入模块.

要解决此问题,有许多可能的策略:

• 使用use ifpragma进行条件导入
• 使用BEGIN块进行条件导入
• require 模块
• 推迟编译 eval

要仅在满足特定条件时导入模块,可以使用ifpragma:

use if $^O eq 'MSWin32', 'Win32';

您还可以在编译期间通过将代码放入BEGIN块来运行代码:

BEGIN {
  if ($^O eq 'MSWin32') {
    require Win32;
    Win32->import;  # probably not necessary
  }
}

BEGIN块的行为与上面完全相同use if.

请注意,我们必须在require这里使用.使用a use Win32,模块将在begin块的编译期间加载,绕过if.在requirebegin块的运行期间加载模块,这是在周围代码的编译期间.

在这两种情况下,Win32模块只能在Windows下导入.这使得MB_ICONINFORMATION非Windows系统上的常量未定义.在这种代码中,最好不要导入任何符号.相反,对所有内容使用完全限定名称,并使用括号进行函数调用(此处为:) Win32::MB_ICONINFORMATION().有了这个改变,只使用一个require而不是一个use if也可以工作.

如果需要稍后运行代码,可以使用字符串eval.但是,这可能会导致安全问题,调试更加困难,并且通常更慢.例如,您可以这样做:

if ($^O eq 'MSWin32') {
    eval q{
        use Win32;    
        Win32::MsgBox("Aloha!", MB_ICONINFORMATION, 'Win32 Msgbox');     
        1;
    } or die $@;  # forward any errors
}

• 因为eval默认情况下会使任何错误无效,所以您必须检查成功并可能重新抛出异常.该1语句确保eval'ed代码在成功时返回true值.如果发生错误则eval返回undef.该$@变量保存最后一个错误.
• q{...}是替代引用构造.除了花括号作为字符串分隔符,它与'...'(单引号)完全相同.

如果您有许多代码仅适用于某个平台,则对每个代码段使用上述策略非常繁琐.相反,为每个平台创建一个模块.例如:

本地/ MyWindowsStuff.pm:

package Local::MyWindowsStuff;
use strict;
use warnings;
use Win32;

sub show_message {
  my ($class, $title, $contents) = @_;
  Win32::MsgBox("Aloha!", MB_ICONINFORMATION, 'Win32 Msgbox');
}

1;

本地/ MyPosixStuff.pm:

package Local::MyPosixStuff;
use strict;
use warnings;

sub show_message {
  warn "messagebox only supported on Windows";
}

1;

在这里,我把它们写成可用作类.然后我们可以有条件地加载其中一个类:

sub load_stuff {
  if ($^O eq 'MSWin32') {
    require Local::MyWindowsStuff;
    return 'Local::MyWindowsStuff';
  }
  require Local::MyPosixStuff;
  return 'Local::MyPosixStuff';
}

my $stuff = load_stuff();

最后,我们不是在代码中添加条件,而是在加载的类上调用方法:

$stuff->show_message('Aloha!', 'Win32 Msgox');

如果您不想创建额外的包,一种策略是评估代码ref:

sub _eval_or_throw { my ($code) = @_; return eval "$code; 1" or die $@ }

my $show_message =
  ($^O eq 'MSWin32') ? _eval_or_throw q{
    use Win32;
    sub {
      Win32::MsgBox("Aloha!", MB_ICONINFORMATION, 'Win32 Msgbox');
    }
  } : _eval_or_throw q{
    sub {
      warn "messagebox only supported on Windows";
    }
  };

然后:$show_message->()调用此代码.这避免了重复编译相同的代码eval.当然,这仅适用于每个脚本运行此代码多次,例如在循环内或子程序中.