未破坏未使用的接口引用

Question

由于不小心使用Delphi接口,我的应用程序中有另一个错误.当我将接口传递给忽略该参数的过程时,实例永远不会被释放.请参阅以下简单示例:

ITest = interface
    procedure Test;
end;

Tester = class(TInterfacedObject, ITest)
public
    procedure Test;
end;

Base = class
public
    procedure UseTestOrNot(test : ITest); virtual; abstract;
end;

A = class(Base)
public
    procedure UseTestOrNot(test : ITest); override;
end;

B = class(Base)
public
    procedure UseTestOrNot(test : ITest); override;
end;

{ A }

procedure A.UseTestOrNot(test: ITest);
begin
    test.Test();
end;

{ B }

procedure B.UseTestOrNot(test: ITest);
begin
    WriteLn('No test here');
end;

// -------- Test ---------------------------------------
var
    list : TObjectList<Base>;
    x : Base;
    t : ITest;
begin
    ReportMemoryLeaksOnShutdown := true;

    list := TObjectList<Base>.Create;
    list.Add(A.Create);
    list.Add(B.Create);

    // 1 x Tester leak for each B in list:
    for x in list do
        x.UseTestOrNot(Tester.Create);

    // this is ok
    for x in list do
    begin
        t := Tester.Create;
        x.UseTestOrNot(t);
    end;

    list.Free;
end.

你能解释参考计数器出了什么问题吗？你能给出任何最佳实践/指南(比如"永远不要在函数调用中创建一个接口实例[如果你不知道里面发生了什么]].

我能想到的最好的解决方案是在Base类中编写一个模板方法,用于保存传递的测试实例并调用抽象DoUseTestOrNot方法.

编辑 Delphi 2010

Answer 1

添加一个guid给你ITest声明

ITest = interface
['{DB6637F9-FAD3-4765-9EC1-0A374AAC7469}']
    procedure Test;
end;

将循环更改为此

for x in list do
    x.UseTestOrNot(Tester.Create as ITest);

GUID是必须能够使用的 as

Test.Create as ITest 使编译器添加创建的对象超出范围的版本.

Answer 2

这是错误的不同体现在这里.
我将把它添加到质量控制报告中.

这不再在Delphi XE update 1中重现.

--jeroen