无法解决:com.google.firebase:firebase-firestore:11.4.2

Question

我正在尝试在已经使用Firebase功能的项目中实现新的Firestore数据库,包括实时数据库 - 我想要"升级".

我正按照本指南工作,但我在编译Firestore库时遇到困难.

这是我目前的项目gradle:

buildscript {
    repositories {
        jcenter()

        maven {
            url 'https://maven.google.com'
        }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.3'
        classpath 'com.google.gms:google-services:3.1.0'


    }
}

allprojects {
    repositories {
        jcenter()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

这是我当前的应用程序gradle:

apply plugin: 'com.android.application'

android {
    compileSdkVersion 25
    buildToolsVersion "25.0.2"
    defaultConfig {
        applicationId "com.tal.wikirace"
        minSdkVersion 23
        targetSdkVersion 25
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    productFlavors {
    }
}

configurations {
    compile.exclude group: "org.apache.httpcomponents", module: "httpclient"
}

dependencies {
    compile fileTree(include: ['*.jar'], dir: 'libs')
    androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })


    compile 'com.android.support.constraint:constraint-layout:1.0.2'
    compile 'com.android.support.constraint:constraint-layout:1.0.2'
    compile 'com.google.api-client:google-api-client:1.22.0'
    compile'com.google.api-client:google-api-client-android:1.22.0'
    compile  'com.android.support:appcompat-v7:25.3.1'
    compile 'com.android.volley:volley:1.0.0'
    compile 'com.google.code.gson:gson:2.7'
    compile 'com.google.code.findbugs:jsr305:2.0.1'
    compile 'com.google.http-client:google-http-client:1.18.0-rc'
    compile 'com.android.support:design:25.3.1'

    compile 'com.google.android.gms:play-services-auth:11.4.2'
    compile 'com.google.firebase:firebase-auth:11.4.2'
    compile 'com.google.firebase:firebase-database:11.4.2'
    compile 'com.google.firebase:firebase-messaging:11.4.2'
}
apply plugin: 'com.google.gms.google-services'

该项目工作正常,但当我尝试添加此行:

compile 'com.google.firebase:firebase-firestore:11.4.2'

我收到这条消息:

Failed To Resolve: com.google.firebase:firebase-firestore:11.4.2

我已经更新Android SDK Build-Tools,Google Play-Services和Support Repository,但它并没有帮助.

我怎样才能解决这个问题？

Answer 1

你错过了allprojects块中的google maven repo:

allprojects {
    repositories {
        jcenter()
         maven {
            url 'https://maven.google.com'
        }
    }
}

如果您使用的是Gradle 4.1或更高版本,则可以简化它:

allprojects {
    repositories {
        jcenter()
        google()
    }
}

allprojects存储库是用于查找应用程序模块的内容.在buildscript中,它仅为gradle插件定位模块.

此外,您应确保所有Firebase模块具有相同的版本.