从两个命名图插入？

Question

我正在寻找一种简单的方法将两个或多个命名图（但不是整个未命名默认图）中的三元组插入到另一个命名图中。 我正在使用 GraphDB。

我想这可以通过在该部分中多次写出相同的查询WHERE，包装在多个 GRAPH规范中，然后将它们联合在一起来完成，但我的WHEREs 很长，我不想多次写出它们。

假设我加载了一些这样的数据：

INSERT DATA {
  GRAPH <http://example.com/ngA> {
    <http://example.com/person1> <http://example.com/name> "Arthur" .
  }
  GRAPH <http://example.com/ngB> {
    <http://example.com/person1> <http://example.com/name> "Brian" .
  }
  GRAPH <http://example.com/ngC> {
    <http://example.com/person1> <http://example.com/name> "Charlie" .
  }
}

我可以将特定模式的所有三元组从默认的未命名图形复制到新的命名图形中，如下所示：

INSERT {
  GRAPH <http://example.com/ngZ> {
    ?s <http://example.com/moniker> ?o .
  }
}
WHERE
  { ?s  <http://example.com/name>  ?o }

SELECT从两个或多个（但不是全部）命名图中获取给定模式的三元组的一种简单方法是

SELECT  *
FROM <http://example.com/ngA>
FROM <http://example.com/ngB>
WHERE
  { ?s  <http://example.com/name>  ?o }

如果我想将这些三元组从那些指定的图形复制到另一个图形中怎么办？

当我尝试执行以下操作时，我从 GraphDB 8.3（以及 sparql.org 验证器）收到错误

INSERT {
  GRAPH <http://example.com/ngZ> {
    ?s <http://example.com/moniker> ?o .
  }
}
WHERE
  { SELECT  *
FROM <http://example.com/ngA>
FROM <http://example.com/ngB>
WHERE
  { ?s  <http://example.com/name>  ?o } }

Answer 1

尝试这个查询：

PREFIX ex: <http://example.com/>

INSERT {
  GRAPH ex:ngZ { ?s ex:moniker ?o }
}
WHERE {
  GRAPH ?g { ?s ex:name ?o }  
  FILTER (?g IN ( ex:ngA, ex:ngB ) )
}

进而：

PREFIX ex: <http://example.com/>

SELECT * 
FROM NAMED ex:ngZ
WHERE { 
    GRAPH ?g { ?s ?p ?o }
} LIMIT 100 

这是你需要的吗？

顺便说一句，存在COPY（谨慎使用！） 和ADD。

Answer 2

SPARQL Update提供USING和USING NAMED类似于查询中的FROM和FROM NAMED：

USING 和 USING NAMED 子句影响评估 WHERE 子句时使用的 RDF 数据集。这以与 FROM 和 FROM NAMED 子句相同的方式描述数据集

您可以将需求表达为 UPDATE，如下所示：

INSERT {
  GRAPH <http://example.com/ngZ> {
    ?s <http://example.com/moniker> ?o .
  }
}
USING <http://example.com/ngA>
USING <http://example.com/ngB>
WHERE
  {  ?s  <http://example.com/name>  ?o }

另请注意，根据SPARQL 查询语法，子查询不接受数据集子句。这就是 SPARQL 解析器拒绝您的查询的原因。