在 org-babel 的 RESULTS 块中启用字体粗细和颜色

Question

有什么方法可以启用#+RESULTS块中的字体粗细和颜色org-babel吗？

例如，使用ls选项--color调用会按照 shell 中的预期呈现字体粗细和颜色，但在#+RESULTS块内呈现时不会呈现：

#+BEGIN_SRC shell
ls --color ~/
#+END_SRC

#+RESULTS:
| Applications      |
| Desktop           |
| Documents         |
| Downloads         |
| Library           |
...

终端中lswith 和 without的屏幕截图--color

另一个例子是nodemodule chalk，它#+RESULTS以明文形式出现在块中：

#+BEGIN_SRC js
const chalk = require('chalk');

console.log(chalk.red('Hello world!'));
#+END_SRC

#+RESULTS:
: Hello world!
: undefined

chalk终端中的屏幕截图

Answer 1

这是我想出的。当光标位于代码块（而不是结果块）上时运行它，将其用作交互式函数。您需要xterm-color安装该软件包。

(defun org-babel-color-results()
  "Color org babel results.
Use the :wrap header argument on your code block for best results.
Without it, org may color overtop with whatever default coloring it
uses for literal examples.
Depends on the xterm-color package."
  (interactive)
  (when-let ((result-start (org-babel-where-is-src-block-result nil nil)))
    (save-excursion
      (goto-char result-start)
      (when (looking-at org-babel-result-regexp)
        (let ((element (org-element-at-point)))
          (pcase (org-element-type element)
            (`fixed-width
             (let ((post-affiliated (org-element-property :post-affiliated element))
                   (end (org-element-property :end element))
                   (contents (org-element-property :value element))
                   (post-blank (org-element-property :post-blank element)))
               (goto-char post-affiliated)
               (delete-region post-affiliated end)
               (insert (xterm-color-filter contents))
               (org-babel-examplify-region post-affiliated (point))
               (insert (make-string post-blank ?\n ))
               ))
            ((or `center-block `quote-block `verse-block `special-block)
             (let ((contents-begin (org-element-property :contents-begin element))
                   (contents-end (org-element-property :contents-end element)))
               (goto-char contents-begin)
               (let ((contents (buffer-substring contents-begin contents-end)))
                 (delete-region contents-begin contents-end)
                 (insert (xterm-color-filter contents)))))))))))

或者添加一个钩子

(add-hook 'org-babel-after-execute-hook 'org-babel-color-results)

这个链接是我的灵感。

我还没弄清楚的一件事是，虽然当您不在代码块上使用参数时它会给文本着色，但 Org Literal Examples:wrap的着色似乎会覆盖它。您可以看到颜色已应用，但是只需删除预期具有颜色的线条即可。 : :