写一个列表解复用器

Question

我正在尝试处理音频信号的通道.我得到信号作为帧的列表,其中每个帧具有每个通道的样本.现在我想独立处理流然后再合并它们.所以我想要

type Sample = Double
type Frame = [Sample]
type Stream = [Sample]
mux :: [Stream] -> [Frame]
demux :: [Frame] -> [Stream]
process :: Stream -> Stream

output = (mux . (map process) . demux) input

mux [[0.1, -0.1, -0.3], [0.2, 0.4, 0.6]] = [[0.1, 0.2], [-0.1, 0.4], [-0.3, 0.6]]
demux [[0.1, 0.2], [-0.1, 0.4], [-0.3, 0.6]] = [[0.1, -0.1, -0.3], [0.2, 0.4, 0.6]]

因为流很长,mux而且demux必须是懒惰的而不是评估整个列表.

多路复用器似乎很简单.我唯一不喜欢这个版本的是难以阅读的模式匹配.

mux streams@((_:_):_) = map head streams : mux (map tail streams)
mux _ = []

但是,我不能轻易想出一个将帧列表转换为流列表的解复用器.因为在我的情况下,也不会有两个以上的数据流(立体声),我想我可以写两个分流器管理monoDemux和stereoDemux.但我希望一个功能可以在任意数量的通道上工作.我怎么能懒得拆分框架列表呢？

Answer 1

我认为,这项工作已经为你做了:既mux和demux,实际上只是transpose :: [[a]] -> [[a]]功能:

import Data.List(transpose)

mux = transpose
demux = transpose

因此,这意味着多路复用实际上(至少就列表列表而言)与多路分解相同.

它产生了预期的:

Prelude Data.List> transpose [[0.1, -0.1, -0.3], [0.2, 0.4, 0.6]]
[[0.1,0.2],[-0.1,0.4],[-0.3,0.6]]
Prelude Data.List> transpose [[0.1, 0.2], [-0.1, 0.4], [-0.3, 0.6]]
[[0.1,-0.1,-0.3],[0.2,0.4,0.6]]

transpose以懒惰的方式工作.我们可以查看源代码:

transpose               :: [[a]] -> [[a]]
transpose []             = []
transpose ([]   : xss)   = transpose xss
transpose ((x:xs) : xss) = (x : [h | (h:_) <- xss]) : transpose (xs : [ t | (_:t) <- xss])

最后一个语句是一个复杂的版本:

transpose l = map head l : transpose (map tail l)