Application Insight Analytics - 查询客户端浏览器和设备

Question

有人知道如何查询 Azure App Insight 以获取客户端设备上的分析吗？或操作系统？我似乎能够在客户国家/地区获得良好的统计数据，但不能在设备上获得

Answer 1

您应该client_CountryOrRegion在现有查询中使用，替换为client_Browser 或其他所需的数据模型。

以下是我曾经在浏览器上查看摘要的一些查询。

pageViews | summarize count() by client_Browser

browserTimings | summarize avg(networkDuration), avg(processingDuration), avg(totalDuration) by name 

更多数据模型参考：https : //docs.microsoft.com/en-us/azure/application-insights/app-insights-export-data-model

Answer 2

由于操作系统和浏览器的细微变化，您可能会收到很多噪音。这是一个提取相同数据的查询，但也简化了值，以便可以更轻松地对它们进行分组

// scalars
let startDate = ago(31d);
let totalCount = toscalar(pageViews | where timestamp > startDate | count);
// query
pageViews
| where timestamp > startDate
| project
    Browser = case(
        client_Browser has "Firefox", "Firefox",
        client_Browser has "Safari", "Safari",
        client_Browser has "Chrome", "Chrome",
        client_Browser has "Samsung", "Samsung",
        client_Browser has "Edg", "Edge",
        client_Browser has "Opera", "Opera",
        client_Browser has "Internet Explorer", "Internet Explorer",
        client_Browser has "Silk", "Amazon Silk",
        client_Browser has "Facebook", "Facebook",
        client_Browser has "Instagram", "Instagram",
        client_Browser has "Apple Mail", "Apple Mail",
        client_Browser has "Android WebKit", "Android WebKit",
        "Other"),
   OS = case(
        client_OS has "iOS", "iOS",
        client_OS has "Android", "Android",
        client_OS has "Mac", "Mac",
        client_OS has "Windows", "Windows",
        client_OS has "Linux", "Linux",
        client_OS has "Chrome OS", "Chrome OS",
        client_OS has "Firefox OS", "Firefox OS",
        "Other")
| summarize Freq = count() by OS, Browser
| project OS, Browser, Freq, Percent = round(100.0 * Freq / totalCount, 2)
| order by Freq desc