'错误:在片段着色器中的GLSL 1.30及更高版本中禁止使用非常量表达式索引的采样器数组

Question

我正在为游戏引擎编写以下片段着色器:

#version 330 core

layout (location = 0) out vec4 color;

uniform vec4 colour;
uniform vec2 light_pos;

in DATA
{
    vec4 position;
    vec2 uv;
    float tid;
    vec4 color;
} fs_in;

uniform sampler2D textures[32];

void main()
{
    float intensity = 1.0 / length(fs_in.position.xy - light_pos);

    vec4 texColor = fs_in.color;

    if(fs_in.tid > 0.0){
        int tid = int(fs_in.tid + 0.5);
        texColor = texture(textures[tid], fs_in.uv);
    }

    color = texColor * intensity;
}

该行texColor = texture(textures[tid], fs_in.uv);导致在编译着色器时,GLSL 1.30及更高版本的表达式中禁止使用非常量表达式索引的采样器数组.

如果需要,顶点着色器是:

#version 330 core

layout (location = 0) in vec4 position;
layout (location = 1) in vec2 uv;
layout (location = 2) in float tid;
layout (location = 3) in vec4 color;

uniform mat4 pr_matrix;
uniform mat4 vw_matrix = mat4(1.0);
uniform mat4 ml_matrix = mat4(1.0);

out DATA
{
    vec4 position;
    vec2 uv;
    float tid;
    vec4 color;
} vs_out;

void main()
{
    gl_Position = pr_matrix * vw_matrix * ml_matrix * position;
    vs_out.position = ml_matrix * position;
    vs_out.uv = uv;
    vs_out.tid = tid;
    vs_out.color = color;
}

Answer 1

在GLSL 3.3中,采样器数组的索引仅允许使用整数常量表达式(参见GLSL 3.3规范,第4.1.7节).

在更现代的版本中,从GLSL 4.0开始,允许通过动态统一表达式对采样器数组进行索引(参见GLSL 4.0规范,第4.1.7节)

你真正想要的是通过变化索引数组,这根本不可能.如果绝对不可避免地这样做,您可以将2d纹理打包成2d数组纹理或3d纹理,并使用索引来处理纹理的图层(或第3维).