如何使用typespecs和Dialyzer with Behaviors？

Question

在Elixir中,我如何记录函数将返回实现特定行为的模块？

要使用一个简单的例子,假设我创建了一个GreeterBehaviour由两个模块实现的行为:

defmodule GreeterBehaviour do
  @callback say_hello(String.t) :: String.t
end

defmodule FormalGreeter do
  @behaviour GreeterBehaviour

  def say_hello(name) do
    "Good day to you #{name}"
  end
end

defmodule CasualGreeter do
  @behaviour GreeterBehaviour

  def say_hello(name) do
    "Hey #{name}"
  end
end

然后,我想通过函数检索Greeter,轻松地换掉这些实现中的任何一个:

defmodule MyApp do
  def main do
    greeter().say_hello("Pete") |> IO.puts
  end

  @spec greeter() :: GreeterBehaviour # This doesn't work with dialyzer
  def greeter do
    FormalGreeter # Can easily be swapped to CasualGreeter
  end
end

Dialyzer将成功检查两者CasualGreeter并FormalGreeter正确实现该GreeterBehaviour行为.但是,我如何定义一个typespec,以便Dialyzer检查greeter/0返回一个实际上实现的模块GreeterBehaviour？

使用@spec greeter() :: GreeterBehaviour不起作用,因为Dialyzer会发出警告:

lib/my_app.ex:19: Invalid type specification for function 'Elixir.MyApp':greeter/0. The success typing is () -> 'Elixir.FormalGreeter'

Answer 1

在你的行为中，你可以定义一个类型say_hello：

@type f :: (String.t() -> String.t())

你的greeter函数可以返回一个模块+函数：&module.say_hello/1

规格是：

@spec greeter() :: GreeterBehaviour.f()

defmodule GreeterBehaviour do
  @type f :: (String.t() -> String.t())
  @callback say_hello(String.t()) :: String.t()
end

defmodule FormalGreeter do
  @behaviour GreeterBehaviour

  def say_hello(name) do
    "Good day to you #{name}"
  end
end

defmodule CasualGreeter do
  @behaviour GreeterBehaviour

  def say_hello(name) do
    "Hey #{name}"
  end
end

defmodule MyApp do
  def main do
    greeter().("Pete") |> IO.puts()
  end

  # This will work with dialyzer
  @spec greeter() :: GreeterBehaviour.f()
  def greeter do
    # Can easily be swapped to CasualGreeter
    &FormalGreeter.say_hello/1
  end
end