如何处理Coq中的Program Fixpoint生成的非常大的术语？

Question

我正在尝试在Coq中定义并证明正确的功能，该功能可以有效地区分两个已排序的列表。由于它并不总是在结构上较小的术语上递归（第一个或第二个列表较小），Fixpoint因此不会接受，因此我尝试使用它Program Fixpoint。

当尝试使用战术simpl或证明功能的性质时program_simpl，Coq会花几分钟的时间进行计算，然后产生一个数百行长的宏术语。我想知道我是在使用Program Fixpoint错误的方式，还是在推理时是否应该使用其他策略而不是简化？

我还想知道，在这样的参数中包括正确性所需的属性是否是一个好习惯，还是最好有一个单独的包装函数，将正确性属性作为参数，并使该函数只接受要比较的两个列表？ ？

请注意，我确实尝试定义了一个更简单的版本make_diff，该版本仅将l1和l2作为参数并固定了类型A和关系R，但是当应用program_simplor simpl策略时，这仍然产生了一个巨大的术语。

*编辑：我的包含项是（尽管此处可能不需要全部包含）：

Require Import Coq.Sorting.Sorted.
Require Import Coq.Lists.List.
Require Import Coq.Relations.Relation_Definitions.
Require Import Recdef.
Require Import Coq.Program.Wf.
Require Import Coq.Program.Tactics.

代码：

Definition is_decidable (A : Type) (R : relation A) := forall x y, {R x y} + {~(R x y)}.
Definition eq_decidable (A : Type) := forall (x y : A), { x = y } + { ~ (x = y) }.

Inductive diff (X: Type) : Type :=
  | add : X -> diff X
  | remove : X -> diff X 
  | update : X -> X -> diff X.

Program Fixpoint make_diff (A : Type) 
    (R : relation A)
    (dec : is_decidable A R)
    (eq_dec : eq_decidable A)
    (trans : transitive A R) 
    (lt_neq : (forall x y, R x y -> x <> y))
    (l1 l2 : list A)
     {measure (length l1 + length l2) } : list (diff A) :=
  match l1, l2 with
  | nil, nil => nil
  | nil, (new_h::new_t) => (add A new_h) :: (make_diff A R dec eq_dec trans lt_neq nil new_t)
  | (old_h::old_t), nil => (remove A old_h) :: (make_diff A R dec eq_dec trans lt_neq old_t nil)
  | (old_h::old_t) as old_l, (new_h::new_t) as new_l => 
    if dec old_h new_h 
      then (remove A old_h) :: make_diff A R dec eq_dec trans lt_neq old_t new_l
      else if eq_dec old_h new_h 
        then (update A old_h new_h) :: make_diff A R dec  eq_dec trans lt_neq old_t new_t
        else  (add A new_h) :: make_diff A R dec eq_dec trans lt_neq old_l new_t 
  end.
Next Obligation.
Proof.
  simpl.
  generalize dependent (length new_t).
  generalize dependent (length old_t).
  auto with arith.
Defined.
Next Obligation.
Proof.
  simpl.
  generalize dependent (length new_t).
  generalize dependent (length old_t).
  auto with arith.
Defined.

Answer 1

在这种特殊情况下，我们可以摆脱Program Fixpoint并使用 plain simple Fixpoint。由于在每次递归调用时，我们make_diff要么在第一个列表的尾部调用，要么在第二个列表的尾部调用，因此我们可以嵌套两个定点函数，如下所示。（我在这里使用了该Section机制来避免传递太多相同的参数）

Require Import Coq.Lists.List.
Import ListNotations.
Require Import Coq.Relations.Relations.

Section Make_diff.

Variable A : Type.
Variable R : relation A.
Variable dec : is_decidable A R.
Variable eq_dec : eq_decidable A.
Variable trans : transitive A R.
Variable lt_neq : forall x y, R x y -> x <> y.

Fixpoint make_diff (l1 l2 : list A) : list (diff A) :=
  let fix make_diff2 l2 :=
  match l1, l2 with
  | nil, nil => nil
  | nil, new_h::new_t => (add A new_h) :: make_diff2 new_t
  | old_h::old_t, nil => (remove A old_h) :: make_diff old_t nil
  | old_h::old_t, new_h::new_t =>
    if dec old_h new_h 
    then (remove A old_h) :: make_diff old_t l2
    else if eq_dec old_h new_h 
         then (update A old_h new_h) :: make_diff old_t new_t
         else (add A new_h) :: make_diff2 new_t
  end
  in make_diff2 l2.

End Make_diff.

请注意，该Section机制不会在生成的签名中包含未使用的参数。这是一个简单的测试：

(* make the first 2 arguments implicit *)    
Arguments make_diff [A R] _ _ _ _.

Require Import Coq.Arith.Arith.

Compute make_diff lt_dec Nat.eq_dec [1;2;3] [4;5;6].
(* = [remove nat 1; remove nat 2; remove nat 3; add nat 4; add nat 5; add nat 6] 
      : list (diff nat) *)