如何在执行时在perl脚本中显示子例程及其名称的数量？

Question

考虑下面的Perl脚本script.pl作为示例:

use strict;
use warnings;
sub f1
{statements}
sub f2
{statements}
sub f3
{statements}
f1();f2();f3();

当我执行脚本时,它应该显示如下输出:

./script.pl

子程序数:3个子程序
名:f1 f2 f3

Answer 1

您正在寻找Devel :: Symdump:

#!/usr/bin/env perl

use strict;
use warnings;

{
    require Devel::Symdump;
    my $sym = Devel::Symdump->new('main');
    my @subs = $sym->functions;
    printf "Number of subroutines: %d\n", scalar @subs;
    printf "Names of subroutines: %s\n", join(q{, } => map { s/^main:://; $_ } @subs);
}

sub f1 {
    # statements
}

sub f2 {
    # statements
}

sub f3 {
    # statements
}

f1();
f2();
f3();

输出:

Number of subroutines: 3
Names of subroutines: f2, f1, f3

Answer 2

Devel :: Examine :: Subs可以做这些类型的事情.

use strict;
use warnings;
use feature 'say';

use Devel::Examine::Subs;

my $des = Devel::Examine::Subs->new(file => $0);

my $subs = $des->objects;

say "number of subs:" . @$subs . "\n";

for my $sub (@$subs){
    say "name:  " . $sub->name;       # name of sub
    say "start: " . $sub->start;      # first line number of sub in file
    say "end: "   . $sub->end;        # last line number of sub in file
    say "lines: " . $sub->line_count; # number of lines in sub
    # $sub->code;                     # entire sub code from file
    # $sub->lines;                    # lines that match search term
    say "\n";
}

sub func1 {}
sub func2 {}
sub func3 {}

输出:

number of subs:3

name:  func3
start: 25
end: 25
lines: 1


name:  func2
start: 24
end: 24
lines: 1


name:  func1
start: 23
end: 23
lines: 1