Perl:使用Moose进行递归对象实例化

Question

在下面的示例代码中,我定义了一个Person可以具有相同类的子对象的类.

当我调用该printTree方法时,我期待以下输出

Sam    Ram    Geeta

我所看到的是

SamRamRamRamRamRamRamRamRamRamRamR.....

关于我做错了什么以及如何实现目标的任何提示？

package Person;

use Moose;

has name => ( is => 'ro' );

my @kids;

sub addChild {
    my ( $self, $name ) = @_;
    my $k = Person->new( name => $name );
    push @kids, $k;
    return $k;
}

sub printTree {
    my $self = shift;
    print $self->name;
    $_->printTree foreach ( @kids );
}



no Moose;

package main;

my $s = Person->new( name => "Sam" );
my $r = $s->addChild( "Ram" );
my $g = $s->addChild( "Geeta" );

$s->printTree;

Answer 1

问题是,@Person::kids它不属于任何一个实例,并且您实际上最终会得到

@Person::kids = ($r, $g);
$s->printTree() loops through @Person::kids, calls
 $r->printTree() loops through @Person::kids, calls
  $r->printTree() loops through @Person::kids, calls
   $r->printTree() loops through @Person::kids, calls
    ...

你需要把它作为一个属性,例如

has kids => (
    isa => 'ArrayRef[Person]',
    traits => ['Array'],
    handles => {
        all_kids => 'elements',
        push_kids => 'push',
    },
    default => sub { [] },
);
sub addChild {
    my ($self, $name) = @_;
    my $k = Person->new(name => $name);
    $self->push_kids($k);
    return $k;
}
sub printTree {
    my ($self) = @_;
    print $self->name;
    $_->printTree foreach $self->all_kids;
}

您可以检查perldoc Moose :: Meta :: Attribute :: Native :: Trait :: Array以获取特征中的其他有用句柄Array.