在Terraform中使用多个user_data文件

Question

我正在尝试为常见任务创建一个公共user_data文件,例如文件夹创建和某些软件包安装,以及一个单独的user_data文件,用于特定于应用程序的配置

我正在尝试以下 -

user_data = "${data.template_file.userdata_common.rendered}", "${data.template_file.userdata_master.rendered}"

有了这些配置 -

通用用户数据模板

data "template_file" "userdata_common" {
  template = "${file("${path.module}/userdata_common.sh")}"

  vars {
    "ALBTarget"          = "${var.ALBTarget}"
    "s3bucket"           = "${var.s3bucket}"
    "centrifydomain"     = "${lookup(var.centrifydomain, format("%s-%s", lower(var.env),var.region))}"
    "centrifyadgroup"    = "${lookup(var.centrifyadgroup, format("%s-%s", lower(var.env),var.region))}"
  }
}

应用程序特定配置

data "template_file" "userdata_master" {
  template = "${file("${path.module}/userdata_master.sh")}"

  vars {
    "ALBTarget"          = "${var.ALBTarget}"
    "s3bucket"           = "${var.s3bucket}"
    "centrifydomain"     = "${lookup(var.centrifydomain, format("%s-%s", lower(var.env),var.region))}"
    "centrifyadgroup"    = "${lookup(var.centrifyadgroup, format("%s-%s", lower(var.env),var.region))}"
  }
}

我做计划时得到以下错误 -

Failed to load root config module: Error parsing /terraform/main.tf: key ${data.template_file.userdata_common.rendered}"' expected start of object ('{') or assignment ('=')

这可能使用Terraform(0.9.3)吗？

如果没有,Terraform最好的方法是什么？

Answer 1

你尝试过template_cloudinit_config吗？

添加以下代码.

data "template_cloudinit_config" "master" {
  gzip          = true
  base64_encode = true

  # get common user_data
  part {
    filename     = "common.cfg"
    content_type = "text/part-handler"
    content      = "${data.template_file.userdata_common.rendered}"
  }

  # get master user_data
  part {
    filename     = "master.cfg"
    content_type = "text/part-handler"
    content      = "${data.template_file.userdata_master.rendered}"
  }

}

# sample code to use it.
resource "aws_instance" "web" {
  ami           = "ami-d05e75b8"
  instance_type = "t2.micro"
  user_data     = "${data.template_cloudinit_config.master.rendered}"
}

如果有效,请告诉我.