如果在运行时间之前我不知道长度,我该如何声明一个数组？

Question

我最初有一个数组[1..1000]被定义为全局变量.但是现在我需要那个是n,而不是1000,直到后来才发现n.我知道在填充数组之前n是什么,但我需要它是全局的,因此需要一种方法来在运行时定义全局数组的大小.

Context使用文件中字节的线性转换填充数组.我不知道文件有多大,直到有人想要打开它并且文件可以是任何大小.

Answer 1

从Delphi 4开始,Delphi支持动态数组.您可以在运行时修改它们的大小,它们将保留您存储在旧大小的其他元素中的数据.它们可以包含任何同类型的元素,包括记录和其他数组.您可以声明一个动态数组,就像声明普通的"静态"数组一样,但只是省略数组边界:

var
  ArthurArray: array of TForm;

虽然静态数组允许您指定下限和上限,但动态数组的低索引始终为零.高索引由High函数给出,它总是返回一个小于数组长度的函数.对于任何动态数组x,High(x) = Length(x)-1.

任何代码都可以访问全局变量,包括本地过程.

动态数组类型的全局变量将初始化为空数组.它的长度为零,并且High调用该数组将为-1.Low在该数组上仍将返回零.

您可以随时调整动态数组的大小.使用该SetLength函数,就像使用字符串一样:

var
  NumElements: Integer;
begin
  NumElements := GetNumberOfArthurForms();
  SetLength(ArthurArray, NumElements);
end;

如果您有一个多维数组,可以在循环中设置它们的长度:

var
  matrix: array of array of Double;
  i: Integer;
begin
  SetLength(matrix, height);
  for i := 0 to height - 1 do
    SetLength(matrix[i], width);
end;

有一个快捷方式可以同时设置所有内部数组的长度:

begin
  SetLength(matrix, height, width);
end;

就像我提到的那样,动态数组在调整大小时会保留旧值:

var
  data: array of string;
begin
  SetLength(data, 2);
  data[1] := 'foo';
  SetLength(data, 20);
  Assert(data[1] = 'foo');
end;

但是如果你缩短数组,那么任何超出新的最后一个元素的元素都将永远消失:

begin
  SetLength(data, 20);
  data[15] := 'foo';
  SetLength(data, 2);
  // data[15] does not exist anymore.
  SetLength(data, 16);
  writeln(data[15); // Should print an *empty* line.
end;

我上面的演示使用了字符串.字符串在Delphi中很特别; 它们由编译器通过引用计数进行管理.因此,string类型的新动态数组元素被初始化为空.但是如果我使用了整数,那么就不能保证新元素的值.它们可能为零,但它们也可能是其他任何东西,就像独立局部变量的初始值一样.

我被告知,Delphi 7的帮助文件非常好.请阅读有关动态数组的更多信息.您可以在Delphi安装中提供的整个VCL和RTL源代码中找到它们的使用示例,以及过去10年中生成的几乎所有Delphi代码示例.