在Visual Studio 2017中使用Windows Silverlight进行开发的解决方案？

Question

我们公司正试图一起删除Visual Studio 2015,但我们仍然有一些Silverlight代码.

有没有一种解决方法能够在VS 2017中使用Silverlight,即使它不受支持,或者更轻量级的解决方案,而不是既要保留IDE,要么只使用2015？

Answer 1

虽然Visual Studio 2017确实不支持Silverlight5项目,但我发现如果安装了Silverlight5 SDK,Visual Studio 2017附带的MSBuild可以构建它们.

我知道这不是一个理想的解决方案,但至少我不需要安装旧的Visual Studio,如果我只需要重建SL5代码.

例如,我使用以下build.bat文件来构建VS2017的SL5项目:

@setlocal

@rem Initialize build environment of Visual Studio 2017
call "c:\Program Files (x86)\Microsoft Visual Studio\2017\Community\Common7\Tools\VsMSBuildCmd.bat"
@echo on

@rem Delete output directory
rmdir /S /Q sl5

@rem Clean project
msbuild ..\src\Pkcs11Interop\Pkcs11Interop\Pkcs11Interop.csproj /p:Configuration=Release /p:Platform=AnyCPU /target:Clean || goto :error

@rem Build project
msbuild ..\src\Pkcs11Interop\Pkcs11Interop\Pkcs11Interop.csproj /p:Configuration=Release /p:Platform=AnyCPU /target:Build || goto :error

@rem Copy result to output directory
mkdir sl5 || goto :error
copy ..\src\Pkcs11Interop\Pkcs11Interop\bin\Release\Pkcs11Interop.dll sl5 || goto :error
copy ..\src\Pkcs11Interop\Pkcs11Interop\bin\Release\Pkcs11Interop.xml sl5 || goto :error

@echo *** BUILD SL5 SUCCESSFUL ***
@endlocal
@exit /b 0

:error
@echo *** BUILD SL5 FAILED ***
@endlocal
@exit /b 1

Answer 2

我使用两个IDE,因为2017年不支持它.该解决方案使用2017年,但如果我必须编辑SL代码,我必须回到以前的IDE版本.

引用Visual Studio 2017平台定位和兼容性

与早期版本的兼容性

安装

您可以安装和使用Visual Studio 2017以及Visual Studio的早期版本,包括Visual Studio 2015,Visual Studio 2013和Visual Studio 2012.

Silverlight的

此版本的Visual Studio不支持Silverlight项目.要维护Silverlight应用程序,请继续使用Visual Studio 2015.

Answer 3

在Silverlight中的Visual Studio在Visual Studio的市场推广非正式支持在Visual Studio 2017年和Visual Studio 2019的Silverlight项目。

免费。

披露：
我发布了 Visual Studio 扩展。