NSIS中的复选框

Question

我正在寻找MUI_PAGE_CUSTOMFUNCTION_SHOW在NSIS中使用的默认目录页中添加一个基本复选框。但是，该复选框似乎没有以任何方式出现或起作用。这是我尝试过的不同功能；我不确定是否需要抓住当前窗口才能绘制它？任何建议将不胜感激。

!define MUI_PAGE_CUSTOMFUNCTION_SHOW "DirectoryShow"
!define MUI_PAGE_CUSTOMFUNCTION_LEAVE "DirectoryLeave"
!insertmacro MUI_PAGE_DIRECTORY

Var Checkbox

Function DirectoryShow
  ${NSD_CreateCheckbox} 0 0 50% 6% "CheckboxTest"
  Pop $Checkbox
  ${NSD_Check} $Checkbox
FunctionEnd

Function DirectoryLeave
  ${NSD_GetState} $Checkbox $0
  ${If} $0 <> 0
    MessageBox mb_ok "Checkbox checked."
  ${EndIf}
FunctionEnd

Answer 1

NSD_Create* 仅在nsDialog页面（“欢迎”和“完成MUI”页面）上受支持，但在内部NSIS页面（如“目录”）上不受支持。

要在内部页面上创建控件，您必须手动调用CreateWindowExWindows API函数。其他一些NSD帮助程序宏仍可以在这些控件上使用：

!include MUI2.nsh
!include nsDialogs.nsh
!define MUI_PAGE_CUSTOMFUNCTION_SHOW "DirectoryShow"
!define MUI_PAGE_CUSTOMFUNCTION_LEAVE "DirectoryLeave"
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE English

Var Checkbox
Var CheckState ; Stored globally so we remember the choice if the user presses the back button and goes back to our page
!define CheckHeight 28

!ifmacrondef _Z= 
!error "NSIS 2.51 or 3.0rc1 or later required!"
!endif
!macro CreateNativeControl hParent cls style exstyle x y w h text ; Note: Only supports pixel coordinates
System::Call 'USER32::CreateWindowEx(i ${exstyle}, t "${cls}", ts, i ${style}, i ${x}, i ${y}, i ${w}, i ${h}, p ${hParent}, i0, i0, i0)p.s' "${text}"
!macroend

Function DirectoryShow
  ; Create some extra space by reducing the height of the top text:
  System::Call *(i,i,i,i)p.r0 ; NSIS 2.51+
  System::Call 'USER32::GetWindowRect(p$mui.DirectoryPage.Text, pr0)'
  System::Call 'USER32::MapWindowPoints(i0,p$mui.DirectoryPage,p$0,i2)'
  System::Call '*$0(i.r2,i.r3,i.r4,i.r5)'
  System::Free $0
  IntOp $5 $5 - ${CheckHeight}
  System::Call 'USER32::SetWindowPos(i$mui.DirectoryPage.Text,i,i,i,i$4,i$5,i0x6)'

  ; Create and initialize the checkbox
  IntOp $5 $3 + $5 ; y = TextTop + TextHeight
  !insertmacro CreateNativeControl $mui.DirectoryPage ${__NSD_CheckBox_CLASS} "${__NSD_CheckBox_STYLE}" "${__NSD_CheckBox_EXSTYLE}" 0 $5 300 ${CheckHeight} "CheckboxTest"
  Pop $Checkbox
  SendMessage $mui.DirectoryPage ${WM_GETFONT} 0 0 $0 ; Get the dialog font
  SendMessage $Checkbox ${WM_SETFONT} $0 1 ; and apply it to the new control
  System::Call 'USER32::SetWindowPos(i$Checkbox,i0,i,i,i,i,i0x33)' ; Make sure it is on top of the tab order
  ${IfThen} $CheckState == "" ${|} StrCpy $CheckState 1 ${|} ; Set the default if this is our first time
  ${NSD_SetState} $Checkbox $CheckState
FunctionEnd

Function DirectoryLeave
  ${NSD_GetState} $Checkbox $CheckState
  ${If} $CheckState <> 0
    MessageBox mb_ok "Checkbox checked."
  ${EndIf}
FunctionEnd

另外，除了在运行时创建控件外，您还可以使用Resource Hacker修改实际页面（... \ NSIS \ Contrib \ UIs \ modern.exe），然后使用MUI_UI（ChangeUI）应用新的UI文件。