VBA 用户窗体刷新

Question

我有一个单词 VBA 用户窗体，我将其用作排行榜来跟踪 SQL 查询更新的结果。有没有办法每 10 分钟启动一次自动刷新表单？我已经尝试过这个：

Private Sub UserForm_Initialize()
Dim cnn As New ADODB.Connection
Dim rst As New ADODB.Recordset
Dim AgingSQL As String

cnn.ConnectionString = "DATABASE INFO"
cnn.Open

AgingSQL = "SQL QUERY"
rst.Open AgingSQL, cnn
rst.MoveFirst
With UserForm1.AgingLeaderboard -- List Box I am using to display info
     .Clear
     Do
        .AddItem
        .List(i, 0) = rst![StatusBy]
        .List(i, 1) = rst![Count]
        i = i + 1
        rst.MoveNext
    Loop Until rst.EOF
End With
rst.Close
**Call Refresh**
End Sub

Sub Refresh()
   Application.OnTime Now + TimeValue("00:00:10"), "UserForm_Initialize"
End Sub

但这似乎没有任何作用。任何帮助表示赞赏！

Answer 1

您不能用来Application.OnTime执行宏以外的任何内容 - 由标准过程模块公开的公共无参数方法。

UserForm_Initialize不是宏- 它是一个事件处理程序，用于处理对象Initialize的事件UserForm。每个实例仅在对象初始化时调用一次。您永远不需要显式调用事件处理程序。如果你发现自己这样做，就应该敲响警钟，应该悬挂巨大的红旗，表明某件事正在做错了。

将您拥有的所有内容UserForm_Initialize移至公共RefreshLeaderboard方法 - 您无需处理Initialize：

Option Explicit

Public Sub RefreshLeaderboard()
    Dim cnn As New ADODB.Connection
    Dim rst As New ADODB.Recordset
    Dim AgingSQL As String

    cnn.ConnectionString = "DATABASE INFO"
    cnn.Open

    AgingSQL = "SQL QUERY"
    rst.Open AgingSQL, cnn
    rst.MoveFirst
    With AgingLeaderboard '-- note: was With UserForm1.AgingLeaderBoard

         .Clear
         Do
            .AddItem
            .List(i, 0) = rst![StatusBy]
            .List(i, 1) = rst![Count]
            i = i + 1
            rst.MoveNext
        Loop Until rst.EOF
    End With
    rst.Close    
End Sub

现在您需要一个可以调度的宏，它可以访问表单实例。

Option Explicit
Private leaderboardForm As MyAwesomeForm ' whatever the UserForm class name is

Public Sub ShowLeaderboard()
    Set leaderboardForm = New MyAwesomeForm
    ScheduleNextRefresh
    leaderboardForm.Show 'vbModal?
    'Set leaderBoardForm = Nothing '' only if the form was modal and not X'd-out
End Sub

Public Sub ScheduleNextRefresh()
    If Not leaderboardForm Is Nothing Then
        leaderboardForm.RefreshLeaderboard
        Application.OnTime Now + TimeValue("00:00:10"), "ScheduleNextRefresh"
    End If
End Sub

您可能需要QueryClose在表单的代码隐藏中处理该事件，以处理由单击 [X] 按钮的用户关闭和/或销毁的事件。