使用`once-only`宏

Question

在实用Common Lisp的第8章末,Peter Seibel展示了once-only宏观.其目的是通过用户定义的宏中的变量评估来缓解一些微妙的问题.注意我在这一点上并没有试图理解这个宏如何工作,就像在其他一些帖子中一样,但是如何正确使用它:

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for n in names collect (gensym))))
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

以下是一个示例(不正确)设计宏,试图展示几个变量评估问题.它声称通过某个delta迭代一系列整数,返回范围:

(defmacro do-range ((var start stop delta) &body body)
  "Sample macro with faulty variable evaluations."
  `(do ((,var ,start (+ ,var ,delta))
        (limit ,stop))
       ((> ,var limit) (- ,stop ,start))
     ,@body))

例如,(do-range (i 1 15 3) (format t "~A " i))应该打印1 4 7 10 13然后返回14.

问题包括1)第二次出现的潜在捕获limit,因为它作为自由变量出现,2)绑定变量的初始出现的潜在捕获limit,因为它出现在表达式中以及出现在宏参数中的其他变量, 3)乱序评估,因为delta之前将进行评估stop,即使stop出现delta在参数列表之前,4)多变量评估,因为stop并且start被评估多次.据我了解,once-only应该解决这些问题:

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
       ,@body)))

但是,(macroexpand '(do-range (i 1 15 3) (format t "~A " i)))抱怨limit成为一个未绑定的变量.如果我切换到with-gensyms,应该只处理上面的问题1和2,扩展将继续进行.

这是once-only宏的一个问题吗？并且once-only确实解决了上面列出的所有问题(也许还有其他问题)？

Answer 1

ONCE-ONLY宏

要删除N未使用的警告,我会将宏更改为:

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for nil in names collect (gensym))))
                           ; changed N to NIL, NIL is ignored
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

此宏的目的是确保表达式仅按定义的顺序进行一次计算.为此,它将引入新的未处理变量,并将评估结果与这些变量绑定.在宏内部,新变量可用.提供宏本身是为了使编写宏更容易.

在DO-RANGE中使用ONCE-ONLY

您的示例使用ONCE-ONLY:

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

为什么会出现LIMIT在once-only列表中？limit在那里是不确定的.LIMIT在ONCE-ONLY表单内部用作符号,但外部没有绑定.

ONCE-ONLY期望名称列表是符号列表,并且这些名称绑定到表单.在你的情况下limit是一个符号,但它是未定义的.

我们需要limit从名单中删除:

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

现在,该怎么办LIMIT？鉴于它once-only提供了名称的绑定,包括for STOP,我们可以消除该符号LIMIT并将其替换为,stop:

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta)))
         ((> ,var ,stop) (- ,stop ,start))
       ,@body)))

例:

CL-USER 137 > (pprint
               (macroexpand
                '(do-range (i 4 10 2)
                   (print i))))

(LET ((#1=#:G2170 4)
      (#3=#:G2171 10)
      (#2=#:G2172 2))
  (DO ((I #1# (+ I #2#)))
      ((> I #3#) (- #3# #1#))
   (PRINT I)))