如何在鼠标区域重叠的 QML TableView 中正确处理鼠标事件？

Question

我有一个附加到我的代表TableViewColumn，其中包含一个MouseArea. 我使用MouseArea来检测对表格中单个单元格的双击，这使我可以显示 以TextField进行编辑。

问题是委托MouseArea阻止鼠标事件传播到TableView. 这意味着 的选择行为TableView不再有效。具体来说，我已经SelectionMode.ExtendedSelection启用。

该MouseArea子项很简单，原来是这样的：

MouseArea{
    id: mousearea
    anchors.fill: parent
    onDoubleClicked: {
        showTextField()
    }
}

查阅文档后，看起来应该可以：

MouseArea{
    id: mousearea
    anchors.fill: parent
    propagateComposedEvents: true        // new
    onDoubleClicked: {
        showTextField()
    }
    onPressed: mouse.accepted = false    // new
}

它确实如此，除了现在我无法再接收双击事件（在 中MouseArea）！这是有道理的，正如文档后面所述：

按下（鼠标事件鼠标）

处理此信号时，使用鼠标参数的接受属性来控制此 MouseArea 是否处理按下和所有未来鼠标事件直到释放。默认是接受该事件并且不允许该事件之下的其他 MouseAreas 处理该事件。如果accepted 设置为false，则在下一次按下按钮之前不会向此MouseArea 发送更多事件。

似乎没有一种方法可以在TableView级别上捕获单个单元格的鼠标事件。这是我第一天玩 QML，所以我可能在这里错过了一些明显的东西，但我有什么选择？注意我使用的是 PyQt。

Answer 1

如果它仅仅是在选择你想才达到你可以手动设置的选择：

TableView {
    id: tv
    itemDelegate: Item {
        Text {
            anchors.centerIn: parent
            color: styleData.textColor
            elide: styleData.elideMode
            text: styleData.value
        }
        MouseArea {
            id: ma
            anchors.fill: parent
            onPressed: {
                tv.currentRow = styleData.row
                tv.selection.select(styleData.row) // <-- select here.
            }
            onClicked: {
                console.log(styleData.value)
            }
        }
    }

    TableViewColumn {
        role: 'c1'
        title: 'hey'
        width: 100
    }
    TableViewColumn {
        role: 'c2'
        title: 'tschau'
        width: 100
    }
    model: lm
}

现在我只选择。但是您可以编写自己的选择/取消选择逻辑。

您还可以从 映射TableView.__mouseArea到委托。

import QtQuick 2.7
import QtQuick.Controls 1.4

ApplicationWindow {
    id: appWindow
    width: 1024
    height: 800
    visible: true

    ListModel {
        id: lm
        ListElement { c1: 'hallo1'; c2: 'bye' }
        ListElement { c1: 'hallo2'; c2: 'bye' }
        ListElement { c1: 'hallo3'; c2: 'bye' }
        ListElement { c1: 'hallo4'; c2: 'bye' }
        ListElement { c1: 'hallo5'; c2: 'bye' }
        ListElement { c1: 'hallo6'; c2: 'bye' }
        ListElement { c1: 'hallo7'; c2: 'bye' }
        ListElement { c1: 'hallo8'; c2: 'bye' }
        ListElement { c1: 'hallo9'; c2: 'bye' }
    }

    TableView {
        id: tv
        itemDelegate: Item {
            id: mydelegate
            signal doubleclicked()
            onDoubleclicked: console.log(styleData.value)
            Text {
                anchors.centerIn: parent
                color: styleData.textColor
                elide: styleData.elideMode
                text: styleData.value
            }

            Connections {
                target: tv.__mouseArea
                onDoubleClicked: {
                    // Map to the clickposition to the delegate
                    var pos = mydelegate.mapFromItem(tv.__mouseArea, mouse.x, mouse.y)
                    // Check whether the click was within the delegate
                    if (mydelegate.contains(pos)) mydelegate.doubleclicked()
                }
            }
        }

        TableViewColumn {
            role: 'c1'
            title: 'hey'
            width: 100
        }
        TableViewColumn {
            role: 'c2'
            title: 'tschau'
            width: 100
        }
        model: lm
    }
}