在"命令存在"中回显是否总是需要在Windows命令提示符下使用双引号？

Question

我试图找到一个文件的存在,然后在命令提示符下打印出如下目录:

C:\> if exist "C:\Program Files(x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" (echo C:\Program Files(x86)\Microsoft Visual Studio 14.0\)

这失败并出现以下错误:

\Microsoft was unexpected at this time.

如果我重写我的命令

C:\> if exist "C:\Program Files(x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" (echo "C:\Program Files(x86)\Microsoft Visual Studio 14.0\")

这打印:

"C:\Program Files(x86)\Microsoft Visual Studio 14.0\"

我使用了这个命令的输出,并且它周围的引号引起了一些问题.有什么办法可以在不添加引号的情况下回应这个问题吗？

Answer 1

问题是该echo部分的括号,结束)时(x86)被认为是(前面开口的对应部分echo.

if exist "C:\Program Files(x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" (echo C:\Program Files(x86)\Microsoft Visual Studio 14.0\)
rem //                                                                         ^                         ^
rem //                                                                         +opening-----------closing+

所以你有两个选择:

1. 要么删除(/ )围绕整个echo命令行:

   if exist "C:\Program Files(x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" echo C:\Program Files(x86)\Microsoft Visual Studio 14.0\
   

2. 或逃避括号(x86),如:

   if exist "C:\Program Files(x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" (echo C:\Program Files^(x86^)\Microsoft Visual Studio 14.0\)
   

   要么:

   if exist "C:\Program Files(x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" (echo C:\Program Files(x86^)\Microsoft Visual Studio 14.0\)
   

条件命令部分周围的括号不是必需的,除非:

1. 你想建立一个多线块:

   if exist "C:\Program Files(x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" (
       echo C:\Program Files^(x86^)\Microsoft Visual Studio 14.0\
   )
   

2. 或者你想使用这个else条款:

   if exist "C:\Program Files(x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" (echo C:\Program Files^(x86^)\Microsoft Visual Studio 14.0\) else echo ERROR: file not found!
   

3. 或以上的组合:

   if exist "C:\Program Files(x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" (
       echo C:\Program Files^(x86^)\Microsoft Visual Studio 14.0\
   ) else (
       echo ERROR: file not found!
   )
   

有关更多信息,请参阅:IF.