如何在一段时间后关闭完成的 Inno Setup 安装程序？

Question

如何在一段时间后关闭“完成”页面上的安装程序？

它也可以解释为：如何在一段时间不活动后关闭安装程序？（关闭/取消安装）。这可能吗？

Answer 1

设置一个计时器，一旦显示“完成”页面即可触发关闭。

[Code]

function SetTimer(hWnd, nIDEvent, uElapse, lpTimerFunc: LongWord): LongWord;
  external 'SetTimer@User32.dll stdcall';
function KillTimer(hWnd, nIDEvent: LongWord): LongWord;
  external 'KillTimer@User32.dll stdcall';

var
  PageTimeoutTimer: LongWord;
  PageTimeout: Integer;

procedure UpdateFinishButton;
begin
  WizardForm.NextButton.Caption :=
    Format(SetupMessage(msgButtonFinish) + ' - %ds', [PageTimeout]);
end;  

procedure PageTimeoutProc(
  H: LongWord; Msg: LongWord; IdEvent: LongWord; Time: LongWord);
begin
  if PageTimeout > 1 then
  begin
    Dec(PageTimeout);
    UpdateFinishButton;
  end
    else
  begin
    WizardForm.NextButton.OnClick(WizardForm.NextButton);
  end;
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID = wpFinished then
  begin
    PageTimeout := 10;
    UpdateFinishButton;
    PageTimeoutTimer := SetTimer(0, 0, 1000, CreateCallback(@PageTimeoutProc));
  end;
end;

function NextButtonClick(CurPageID: Integer): Boolean;
begin
  if CurPageID = wpFinished then
  begin
    KillTimer(0, PageTimeoutTimer);
    PageTimeoutTimer := 0;
  end;
  Result := True;
end;

对于CreateCallback函数，您需要 Inno Setup 6。如果您无法使用 Inno Setup 5，您可以使用InnoTools InnoCallbackWrapCallback库中的函数。

相关问题：

• MsgBox - 制作不可点击的OK按钮并改为倒计时 - Inno Setup ;
• Inno Setup - 自动提交卸载提示。