perl6需要帮助来了解有关proto正则表达式/令牌/规则的更多信息

Question

以下代码取自perl6网站教程,我试图在更多实验之前了解更多信息:

proto token command {*}
      token command:sym<create>   { <sym> }
      token command:sym<retrieve> { <sym> }
      token command:sym<update>   { <sym> }
      token command:sym<delete>   { <sym> }

1. 是*在第一线的任何明星？它可以是别的东西,比如

   proto token command { /give me an apple/ }
   

2. "sym"可以是其他东西,例如

   command:eat<apple> { <eat> } ?
   

Answer 1

{*}告诉运行时调用正确的候选者.编译器允许您将其缩短为正确,
而不是强迫您编写{{*}}只调用正确的常见情况{*}

这是所有的情况proto类似程序sub,method,regex,token,和rule.

在regex原型例程中,只{*}允许裸露.
主要原因可能是因为没有人真正想出一种让它在正则表达式子语言中合理运行的好方法.

所以这里有一个例子,proto sub它做了一些对所有候选人都很常见的事情.

#! /usr/bin/env perl6
use v6.c;
for @*ARGS { $_ = '--stdin' when '-' }

# find out the number of bytes
proto sub MAIN (|) {
  try {
    # {*} calls the correct multi
    # then we get the number of elems from its result
    # and try to say it
    say {*}.elems #            <-------------
  }
  # if {*} returns a Failure note the error message to $*ERR
  or note $!.message;
}

#| the number of bytes on the clipboard
multi sub MAIN () {
  xclip
}

#| the number of bytes in a file
multi sub MAIN ( Str $filename ){
  $filename.IO.slurp(:!chomp,:bin)
}

#| the number of bytes from stdin
multi sub MAIN ( Bool :stdin($)! ){
  $*IN.slurp-rest(:bin)
}

sub xclip () {
  run( «xclip -o», :out )
  .out.slurp-rest( :bin, :close );
}