获取序列的基础类型(数组,列表,seq)

Question

鉴于type具有各种属性,如何在属性时提取属性类型array,list或者seq？

示例代码如下

type Car = { name: string }
type CarStore = 
    { name: string
    cars: Car[]
    names: string list
    others: string seq
    others2: ResizeArray<string> }

let peek x =
    Dump x
    x

let extractTypeInfo name (typ:Type) =
    let isEnumerable = true //todo: true for list, array, seq, etc
    let underlyingType = typ //todo: if isEnumerable = true, get actual type
    isEnumerable, underlyingType

typeof<CarStore>.GetProperties()
|> peek
|> Seq.map (fun p -> extractTypeInfo p.Name p.PropertyType)
|> Dump

执行以上属性,

• 名称: String
• 汽车: IStructuralEquatable[]
• 名称: FSharpList<String>
• 其他: IEnumerable<String>
• 其他2: List<String>

应该如何extractTypeInfo更新,以便结果将具有以下信息

• 名称: String
• 汽车: Car
• 名称: String
• 其他: String
• 其他2: String

Answer 1

我倾向于做这样的事情:

let extractTypeInfo (typ:Type) =
    typ.GetInterfaces()
    |> Array.tryFind (fun iFace -> 
        iFace.IsGenericType && iFace.GetGenericTypeDefinition() = typedefof<seq<_>>)
    |> Option.map (fun iFace -> iFace.GetGenericArguments().[0]) 

这种方法捕获类型是否是一个seq<'T>通过返回Some或None和的类型'T的结果内Some的情况.

FSI中的一些例子:

extractTypeInfo typeof<float array>;;
val it : System.Type option =
  Some
    System.Double ...

extractTypeInfo typeof<string list>;;
val it : System.Type option =
  Some
    System.String ...

extractTypeInfo typeof<int>;;
val it : System.Type option = None

Answer 2

@TheInnerLight的答案提供了一个很好的工作解决方案,但与往常一样反思,你应该非常清楚你真正想要看到什么以及你真正关注的是什么.

我觉得这里有两点值得注意:

1. 虽然F#类型系统使数组看起来像正确的通用类型,但这并不是它们在.NET反射API中的表现.给定一个数组类型,你将得到typ.IsGenericType等于false,但typ.IsArray等于true,你可以得到类型参数typ.GetElementType().这是出于历史原因,因为反射API早于.NET泛型.
2. 您正在查看类型上的IEnumerable<'a>接口实现的泛型类型参数- 并且仅在此处.这意味着虽然类型和接口的泛型类型参数是相同的,但如果你只考虑列表,seqs和数组,在一般情况下它不是给定的.您可以使用与其IEnumerable<'a>实现不同的类型参数实例化泛型类型(这是地图和字典的情况),或者具有多个实现IEnumerable<'a>(在这种情况下,此解决方案将获取它找到的第一个).

这些可能不是您可能立即发现对您的解决方案重要的事情,但您可能会及时发现它们.