MS Excel - 带分隔符的Concat

Question

我有一个带有数字的长电子表格.

我需要将它们分成一个字符串; 例如.4364453; 24332432; 2342432

我知道我能做到:

=concat(A1:A2000)

但是这将在没有分隔符的情况下将其合并到一个字符串中 - 当您指定范围时,我似乎无法找到分隔符的选项.

谢谢

Answer 1

使用TEXTJOIN()代替:

=TEXTJOIN(";",TRUE,A1:A2000)

对于那些没有OFFICE 365 Excel的用户,请使用模仿TEXTJOIN函数的UDF.

将其放在工作簿附带的模块中,并使用上面的公式进行调用.

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function