将 C++11 数组与 Cython 接口

Question

我习惯于构建 C++ 程序并在 Cython 中获取它，但在这里我试图获取 C++ 11array并且它绝对不起作用。

这是我的 .pxd ：

cdef extern from "<array>" namespace "std" nogil :
    cdef cppclass array[T, size_t]:
        ctypedef T value_type
        cppclass iterator:
            T& operator*()
            iterator operator++()
            iterator operator--()
            iterator operator+(size_t)
            iterator operator-(size_t)
        bint operator==(iterator)
        bint operator!=(iterator)
        bint operator<(iterator)
        bint operator>(iterator)
        bint operator<=(iterator)
        bint operator>=(iterator)
        T& operator[](size_t)
        array() except +
        array(array&) except +

这个文件的大部分内容是从“vector.pxd”改编的，但我删除了分配器，因为 c++11array不需要它。我用作size_t第二个模板参数，但我不确定。

问题是，当我这样做时：

    from array11 cimport array
    cdef array[int, 5] test   

我得到，编译时：

模板参数中的未知类型

如果我做 ：

    from array11 cimport array
    cdef array[int, 5] * test = new array[int, 5]()

我得到：

new 运算符只能应用于 C++ 类

知道我做错了什么吗？

谢谢！

Answer 1

正如评论中所讨论的，您遇到的问题是因为 Cython 并不真正支持非类型模板参数。一个解决方法（hacky 并且可能很脆弱）是欺骗 Cython 认为它提供了一个类型模板参数：

cdef extern from "<array>" namespace "std" nogil :
    cdef cppclass two "2":
        pass

    cdef cppclass array[T, U]:
        T& operator[](size_t)
        # this is obviously very very cut down

def f():
    cdef array[int,two] x
    return x[0]+x[1]

诀窍是，如果你这样做cdef cppclass name "somestring"Cython 只会盲目地替换somestring名称，从而生成正确的 C++ 代码。这种方法显然有一些限制，但对于简单的使用来说应该没问题。