Lisp:多维数组元素运算

Question

Common Lisp中将元素操作应用于多维数组的"正确"构造是什么？

以下示例应该有助于说明我正在尝试做的事情:

A)假设我想将数组的每个元素增加一个:

0 1 2    1 2 3
3 4 5 -> 4 5 6
6 7 8    7 8 9

B)假设我想添加2个数组:

1 2   -1 -1    0 1
3 4 + -2 -2 -> 1 2
5 6   -3 -3    2 3

C)假设我想找到几个数组中最大的元素,元素:

max( 0 1 , 4 -1 , 0 0 ) -> 4 1
     2 3   0  0   8 1      8 3

基本上我认为我正在寻找某种"arraymap"函数,它可以像这样使用:(arraymap f A1 A2 ... An)其中f将n个参数作为输入,而Ai是相同大小的数组.

在上面的例子中,它将被如下使用:

一个)

(setq M #2A((0 1 2) (3 4 5) (6 7 8)))
(arraymap #'incf M)

B)

(setq M #2A((1 2) (3 4) (5 6)))
(setq N #2A((-1 -1) (-2 -2) (-3 -3)))
(arraymap #'+ M N)

C)

(setq M #2A((0 1) (2 3)))
(setq N #2A((4 -1) (0 0)))
(setq O #2A((0 0) (8 1)))
(arraymap #'max M N O)

我尝试了一些带有map和loop的结构,但是由于多维数组不是序列类型,所以它似乎不起作用.

Answer 1

有四种方法可以做到这一点:

• 根据数组维度编写ARRAY-MAP函数并迭代这些函数.

• 使用ROW-MAJOR-AREF,它像向量一样查看数组.

• 使用移位的一维数组进行操作.

使用移位数组的示例:

(defun array-map (function &rest arrays)
  "maps the function over the arrays.
   Assumes that all arrays are of the same dimensions.
   Returns a new result array of the same dimension."
  (flet ((make-displaced-array (array)
           (make-array (reduce #'* (array-dimensions array))
                       :displaced-to array)))
    (let* ((displaced-arrays (mapcar #'make-displaced-array arrays))
           (result-array (make-array (array-dimensions (first arrays))))
           (displaced-result-array (make-displaced-array result-array)))
      (declare (dynamic-extent displaced-arrays displaced-result-array))
      (apply #'map-into displaced-result-array function displaced-arrays)
      result-array)))

使用它:

CL-USER 3 > (array-map #'1+ #2A((0 1 2) (3 4 5) (6 7 8)))

#2A((1 2 3) (4 5 6) (7 8 9))

CL-USER 4 > (array-map #'+ #2A((1 2) (3 4) (5 6)) #2A((-1 -1) (-2 -2) (-3 -3)) )

#2A((0 1) (1 2) (2 3))

• 使用内部的,特定于实现的操作来实现高效的阵列操作