VB.net Integer 和 Short 转换，GetMessagePos()

Question

我正在尝试在 VB.net 中使用DWORD WINAPI GetMessagePos(void)函数。

该函数返回一个 DWORD（32 位），它可以存储在 VB.net 整数变量中。引用自 MSDN 文档：

x 坐标在返回值的低位；y 坐标在高阶 short（两者都表示有符号值，因为它们可以在具有多个监视器的系统上取负值）

如何使用 vb.net 检索 x 和 y 坐标？

我目前正在尝试

<System.Runtime.InteropServices.DllImport("user32.dll", ExactSpelling:=True)>
Private Shared Function GetMessagePos() As Integer
End Function
Sub test()
    Dim pos As Integer = GetMessagePos()

    Try
        Dim x As Short = CShort(pos And &HFFFF)
        Dim y As Short = CShort(pos >> 16)

        MessageBox.Show(x & ", " & y)
    Catch ex As Exception
        MessageBox.Show(ex.Message)
    End Try
End Sub

但我不确定这是否是正确的做法。我正在尝试做一些测试，比如

    Try
        Dim x As Short = -1
        Dim y As Short = 1

        Dim i As Int32 = (y << 16) Or x

        Dim x2 As Short = CShort(i And &HFFFF)
        Dim y2 As Short = CShort(i >> 16)

        MessageBox.Show(x & ", " & y)
    Catch ex As Exception
        MessageBox.Show(ex.Message)
    End Try

基本上我在 Short (Int16) 变量中编码 x 和 y 坐标，将它们放在一个 Int32 中，然后尝试解码。
但它似乎不起作用，因为它会导致溢出。

关于如何从GetMessagePos()WINAPI解码 xy 坐标的任何想法？

Answer 1

提取这些值时必须小心，以确保它们在多监视器系统上正常工作。就您通常与GetMessagePos函数一起使用的内容而言，执行此操作的“标准”方法是Windows SDK 标头中定义的GET_X_LPARAM和GET_Y_LPARAM宏。这些在GetMessagePos文档中特别提到，并且在所有文档中都应该有类似的参考，用于返回压缩坐标的函数。还有一个警告不要使用经典LOWORD或HIWORD宏，因为它们将值视为无符号数量，正如您在问题中提到的。

因此，任务本质上是将GET_X_LPARAM和GET_Y_LPARAM宏从 C 转换为 VB.NET。将它们转换为 C# 相对简单，因为您可以利用unchecked关键字：

int GetXValue(UInt32 lParam)
{
    return unchecked((short)(long)lParam);
}

int GetYValue(UInt32 lParam)
{
    return unchecked((short)((long)lParam >> 16));
}

但是 VB.NET 没有 C#unchecked关键字的等效项，因此您必须找到其他方法来避免溢出。就我个人而言，我用 C# 编写这种互操作代码并将其粘贴在一个库中，这样我就可以做我认为最易读的事情。

如果您更喜欢坚持使用 VB.NET，有几种方法可以做到。最简单的概念是将值作为 aUInt32进行操作以避免溢出。对于低位的 x 坐标，您需要显式屏蔽高位以避免溢出。对于 y 坐标，您需要移动和屏蔽。然后你可以转换回 a Short：

Public Function GetXValue(lParam As UInt32) As Short
    Return CShort(lParam And &HFFFF)
End Function

Public Function GetYValue(lParam As UInt32) As Short
    Return CShort((lParam >> 16) And &HFFFF)
End Function

另一种选择更聪明一点，也许太聪明了，但可能更有效。它涉及声明 C 风格联合的等价物，在 VB.NET 术语中，它只是一个字段重叠的结构：

<StructLayout(LayoutKind.Explicit)> _
Public Structure CoordUnion

    <FieldOffset(0)> Public LParam As UInt32
    <FieldOffset(0)> Public XCoord As Short
    <FieldOffset(2)> Public YCoord As Short

    Public Sub New(lParam As UInt32)
        LParam = lParam
    End Sub

End Structure

然后你可以像这样使用它：

Dim temp As CoordUnion = New CoordUnion(GetMessagePos())
Dim pt As Point = New Point(temp.XCoord, temp.YCoord)
' ...

另请注意，我已经隐式更改了 P/Invoke 签名，GetMessagePos以便它返回一个UInt32：

<System.Runtime.InteropServices.DllImport("user32.dll", ExactSpelling:=True)>
Private Shared Function GetMessagePos() As UInt32
End Function

您可以像使用IntPtr类型一样轻松地在所有这些帮助器/转换函数中使用UInt32类型。事实上，这就是您通常的编写方式，因为您通常将这些指针坐标打包成一个lParam值作为窗口消息的一部分（例如，当覆盖WndProc控件的方法时）。