SWI-prolog中的动态规则断言

Question

我正在尝试使用SWI-prolog动态地向知识库添加规则,其中规则的主体事先是未知的.

所需的规则如下所示:

rule(a) :- fact(1), fact(2).

通常你会简单地说

assert((rule(a):-fact(1),fact(2))).

但问题是事实是在运行时决定的(在断言之前事实的数量也是未知的).

这就是为什么我想知道是否有可能主张一个规则,其中正文由一系列事实组成,如[fact(1),fact(2)]

Answer 1

我们将创建一个规则newrule(X) :- w,x,y,z(X).
规则的主体是一个元组,一个形式的构造(w,x,y ......).

对于不同的身体长度,从没有身体开始:

assert(goal).  
assert(goal:-cond).  
assert(goal:-(cond1,cond2)).

元组运算符是逗号(`,'),如','(a,b)==(a,b).

%%%%
%%%% Name: runtime.pl -- Runtime rule insertion.
%%%%
create_a_rule :- 
    Cond=[w,x,y,z(X)],
    Head=newrule(X),
    list_to_tuple(Cond,Body),
    dynamic(Head),
    assert(Head :- Body),
    listing(Head).

/*
This is a [l,i,s,t], and this is a (t,u,p,l,e).  
Convertng list to tuple:  
[]    -> undefined  
[x]   -> (x) == x  
[x,y] -> (x,y).  
[x,y,z..whatever] = (x,y,z..whatever)  
*/

list_to_tuple([],_) :- 
    ValidDomain='[x|xs]',
    Culprit='[]',
    Formal=domain_error(ValidDomain, Culprit),
    Context=context('list_to_tuple','Cannot create empty tuple!'),
    throw(error(Formal,Context)).

list_to_tuple([X],X).

list_to_tuple([H|T],(H,Rest_Tuple)) :-
    list_to_tuple(T,Rest_Tuple).

:- create_a_rule.
:- listing(newrule).

-

有两个列表.第一个列表来自listing()被调用create_a_rule().第二个列表来自listing()最后一个源代码行的命令.

?- [runtime].
:- dynamic newrule/1.

newrule(A) :-
    w,
    x,
    y,
    z(A).

:- dynamic newrule/1.

newrule(A) :-
    w,
    x,
    y,
    z(A).

% runtime compiled 0.01 sec, 1,448 bytes
true.