在CMAKE中链接到ExternalProject_add依赖项

Question

运行忍者时，我在下面收到此忍者构建错误。我的CMAKE构建命令是cmake -G"Ninja" -DCMAKE_BUILD_TYPE=Release。

ninja: error: 'ext_deps/api/src/ext_api/build/src/lib/libapi.a', needed by 'Project', missing and no known rule to make it

假设我的项目由一个API（通过CMAKE从GitHub下载）和实现（该项目）组成。

The layout would look like:
Project/
-- build/
-- cmake/modules
----- ExternalDep.cmake
----- FindAPI.cmake
-- CMakeLists.txt
-- src/
---- CMakeLists.txt
-- include/

假设在顶层，CMakeLists.txt我通常执行设置构建设置，CXX标志等的工作，然后调用include(ExternalDep)，它检查“ API”库是否在用户系统中（如果不是，则通过CMAKE下载） ）。在src/CMakeLists.txt我尝试使用

target_link_libraries(${PROJECT_NAME} PRIVATE ${API_LIBRARY})

我遇到的第一个问题是，在甚至可以下载和构建“ API”库之前，我会收到上面发布的忍者构建错误。我很肯定在ExternalDep.cmake尝试添加Project可执行文件并针对“ API”库进行链接之前已将其包含在内。

这是的简化版本ExternalDep.cmake：

  set(EXT_DEPS_PREFIX "ext_deps")

  ExternalProject_Add(ext_lib
    GIT_REPOSITORY "https://github.com/fake/api.git"
    GIT_TAG "master"
    PREFIX "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api"
    TMP_DIR "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api-tmp"
    STAMP_DIR "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api-stamp"
    CMAKE_ARGS -DCMAKE_BUILD_TYPE=Release
    SOURCE_DIR "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api/ext_api"
    BINARY_DIR "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api/ext_api-build"
    BUILD_ALWAYS true
    TEST_COMMAND "")

  add_dependencies(ext_projects ext_api)

  set(API_LIBRARY "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api/ext_api-build/src/lib/libapi.a")

Answer 1

当与配合使用Ninja时，我遇到了同样的问题Unix Makefiles，并Ninja通过BUILD_BYPRODUCTS在代码ExternalProject_Add块中添加一行来设法使其与之配合使用。例：

    ExternalProject_Add(SDL2_PROJECT
        PREFIX 3rdparty
        URL https://www.libsdl.org/release/SDL2-2.0.5.tar.gz
        URL_MD5 d4055424d556b4a908aa76fad63abd3c
        CONFIGURE_COMMAND <SOURCE_DIR>/configure ${SDL2_configure_args} --prefix=<INSTALL_DIR> --disable-shared
        INSTALL_COMMAND make install -j9
        BUILD_BYPRODUCTS <INSTALL_DIR>/lib/libSDL2.a
    )
    ExternalProject_Get_Property(SDL2_PROJECT INSTALL_DIR)
    set(SDL2_INSTALL_DIR ${INSTALL_DIR})
    add_library(SDL2_LIBRARY STATIC IMPORTED GLOBAL)
    set_property(TARGET SDL2_LIBRARY PROPERTY IMPORTED_LOCATION ${SDL2_INSTALL_DIR}/lib/libSDL2.a)
    add_dependencies(SDL2_LIBRARY SDL2_PROJECT)

Answer 2

我能够通过生成 Unix Makefiles 而不是 Ninja 来解决这个问题。我仍然不确定这是否是唯一的问题，但这绝对是问题之一。