F# - 拼合列表/范围

Question

我是F#的新手,我想知道如何平整列表.

基本上在数据库中我存储了一个带有min_age和max_age范围的记录(为了简洁起见,这是一个虚构的例子 - 我不是很疯狂!).我的字段看起来如下所示:

id,cost,savings,min_age,max_age

我本质上有一个F#类,它充当与该表的一对一映射 - 即所有属性都精确映射到数据库字段.

我想做的是平整这个范围.所以,而不是包含这样的项目的列表:

saving_id = 1, cost = 100, savings = 20, min_age = 20, max_age = 26
saving_id = 2, cost = 110, savings = 10, min_age = 27, max_age = 31

我想要一个包含这样的项目的列表:

saving_id = 1, cost = 100, savings = 20, age = 20
saving_id = 1, cost = 100, savings = 20, age = 21
etc.
saving_id = 2, cost = 110, savings = 10, age = 27
saving_id = 2, cost = 110, savings = 10, age = 28
etc.

是否有任何内置机制以这种方式展平列表和/或是否有人知道如何实现这一目标？提前致谢,

J.P

Answer 1

您可能想要使用Seq.collect.它将序列连接在一起,因此在您的情况下,您可以在输入上映射一个函数,该函数将单个年龄范围记录拆分为一系列年龄记录,并使用Seq.collect将它们粘合在一起.

例如:

type myRecord =
{ saving_id: int;
  cost: int;
  savings: int;
  min_age: int;
  max_age: int }

type resultRecord =
    { saving_id: int;
      cost: int;
      savings: int;
      age: int }

let records = 
    [ { saving_id = 1; cost = 100; savings = 20; min_age = 20; max_age = 26 }
      { saving_id = 2; cost = 110; savings = 10; min_age = 27; max_age = 31 } ]

let splitRecord (r:myRecord) =
    seq { for ageCounter in r.min_age .. r.max_age -> 
            { saving_id = r.saving_id;
              cost = r.cost;
              savings = r.savings;
              age = ageCounter }
    }

let ageRanges = records |> Seq.collect splitRecord

编辑:您还可以使用带有产量的序列生成器!

let thisAlsoWorks = 
    seq { for r in records do yield! splitRecord r }