如何将XML元素组转换为JSON列表？

Question

是否可以应用仅与唯一属性匹配的模板？

<node name="region">1</node>
<node name="region">2</node>
<node name="region">3</node>
<node name="place">a</node>
<node name="place">b</node>
<node name="title">test</node>

我想一次执行一个模板,@name="region"并一次@name="place".可以使用XSLT/XPath 1.0完成吗？

我的最终目标是JSON输出,如下所示:

"container":{
"region":["1","2","3"],
"place":["a","b"],
"title":"test"
}

Answer 1

Muenchian分组方法

您可以使用Muenchian方法来解决分组问题.

这个输入XML,

<container>
  <node name="region">1</node>
  <node name="region">2</node>
  <node name="region">3</node>
  <node name="place">a</node>
  <node name="place">b</node>
  <node name="title">test</node>
</container>

提供给这个XSLT,

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="text"/>

  <xsl:key name="nodes-by-name" match="node" use="@name"/>

  <xsl:template match="container">
    <xsl:text>"container": {&#xa;</xsl:text>
      <xsl:for-each select="node[count(. | key('nodes-by-name', @name)[1]) = 1]">
      <xsl:value-of select="concat('&quot;', @name, '&quot;:')"/>
      <xsl:choose>
        <xsl:when test="count(key('nodes-by-name', @name)) = 1">
          <xsl:value-of select="concat('&quot;', ., '&quot;')"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:text>[</xsl:text>
          <xsl:for-each select="key('nodes-by-name', @name)">
            <xsl:value-of select="concat('&quot;', ., '&quot;')"/>
            <xsl:if test="position() != last()">,</xsl:if>
          </xsl:for-each>
          <xsl:text>]</xsl:text>
        </xsl:otherwise>
      </xsl:choose>
      <xsl:if test="position() != last()">,</xsl:if>
      <xsl:text>&#xa;</xsl:text>
    </xsl:for-each>
    <xsl:text>}</xsl:text>
  </xsl:template>

</xsl:stylesheet>

产生这个XML输出,

"container": {
"region":["1","2","3"],
"place":["a","b"],
"title":"test"
}

按照要求.