VLC语法转码和流到stdout？

Question

目标:我想使用VLC作为本地服务器来扩大与创建一个应用程序的视频功能Adobe AIR,Flex和Actionscript.我正在使用VLC流式传输stdout并从我的应用程序中读取该输出.

VLC流媒体功能
VLC Flash视频
流VLC到网站的asf和Flash

状态:我可以VLC作为后台进程启动并通过其远程控制界面控制它(更多细节).我可以加载,转码和流式传输本地视频文件.下面的示例应用程序是一个准确证明这一点的准系统测试平台.

问题:我正在将数据输入到我的应用程序中,但它不会呈现为视频.我不知道我的VLC命令或写入/读取是否有问题stdout.这种从stdoutAIR 中读取的技术(ffmpeg例如).

我试过的各种转码命令之一:

-I rc  // remote control interface  
-vvv   // verbose debuging  
--sout  // transcode, stream to stdout 
"#transcode{vcodec=FLV1}:std{access=file,mux=ffmpeg{mux=flv},dst=-}"

这将导致数据进入到我的应用程序,但由于某种原因,使用时未呈现,视频appendBytes与NetStream实例.

相反,如果我将数据写入.flv文件,则会创建一个有效的文件 - 因此损坏的部分似乎正在写入stdout.有一点我注意到:我没有通过stdout`方法获取元数据.如果我播放使用以下命令创建的文件,我会看到元数据.

// writing to a file
var output:File = File.desktopDirectory.resolvePath("stream.flv");
var outputPath:String = output.nativePath;
"#transcode{vcodec=FLV1}:std{access=file,mux=ffmpeg{mux=flv},dst=" + outputPath + "}");

---

希望有人看到我在这里出错的地方.

---

更新1:只是添加更多细节(!) - 我看了一下生成的.flv文件来检查元数据.它出现在文件的头部,如下所示.onMetaData如果我从磁盘播放文件,我设置了正确的处理程序并查看此数据的跟踪.在阅读stdout和NetStream处于Data Generation模式时,我没有看到此痕迹.是否有可能stdout因某种原因没有被发送？我已经尝试生成自己的标头并在流开始之前附加它 - 我可能没有正确的标头格式.

---

更新2:所以在我的AIR应用程序中,我能够粗略地解析stdout来自的传入流VLC.我想知道是否正在发送FLV标头数据 - 而且它似乎是.我不知道它是否是正确的格式等,但正如我上面提到的,如果我写入.flv文件而不是stdout,则会创建一个有效的.flv文件.

现在完全不知所措 - 尝试了我能想到的一切,并跟进了我可以在所涉及的问题上找到的每个网络链接.唉 - 如此接近,VLC从内部利用它会很酷AIR.

---

更新3:根据VC ONE's建议,我使用他/她的示例代码检查传入的字节是否有正确的数据.我得到一个巨大的字符串(1000的字符),但这些是第一个:

    What I get:
    464C560105000000090000000012000111000000000000000200
    46 4C 56 01 05 00 00 00 09 00 00 00 00 // check outs  

    What it should be:
    46 4C 56 01 05 00 00 00 09 00 00 00 00

---

注意:为了使其在AIR中起作用,您需要将应用程序配置文件定义为"extendedDesktop"

---

  <?xml version="1.0" encoding="utf-8"?>
  <s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/mx"
                       width="1024" height="768"
                       showStatusBar="false"
                       applicationComplete="onApplicationCompleteHandler(event)">

    <fx:Script>
        <![CDATA[
            import mx.events.FlexEvent;

            public var dataIn:Number = 0;
            public var dataTotal:Number = 0;
            private var processExe:File;
            private var processArgs:Vector.<String>;
            private var process:NativeProcess;
            private var nc:NetConnection;
            private var ns:NetStream;
            private var vid:Video;

            private var videoPath:String; // video to be streamed

            protected function onApplicationCompleteHandler(event:FlexEvent):void {
                var testFile:File = File.desktopDirectory.resolvePath("test.mp4");
                if (testFile.exists){
                    videoPath = testFile.nativePath;
                }

                setUpNetStream();
                createNativeProcess();
                startNativeProcess();
            }

            protected function setUpNetStream():void {
                nc = new NetConnection();
                nc.addEventListener(AsyncErrorEvent.ASYNC_ERROR, errorHandler);
                nc.addEventListener(NetStatusEvent.NET_STATUS, connStatusHandler);
                nc.connect(null);

                ns = new NetStream(nc);
                ns.addEventListener(AsyncErrorEvent.ASYNC_ERROR, errorHandler);
                ns.addEventListener(NetStatusEvent.NET_STATUS, streamStatusHandler);

                var client:Object = new Object();
                client.onMetaData = onMetaDataHandler;
                ns.client = client;

                vid = new Video(640,480);
                vid.x= 100;
                vid.y = 200;

                this.stage.addChild(vid);

                vid.attachNetStream(ns);
                ns.play(null);
            }

            private function createNativeProcess():void {
                if(NativeProcess.isSupported) {
                    // This is for OSX; 
                    var pathToVLC:String = "utils/OSX/VLC.app/Contents/MacOS/VLC";
                    processExe = File.applicationDirectory.resolvePath(pathToVLC);

                    if (processExe.exists){
                        process = new NativeProcess();
                        process.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, onOutputData); 
                        process.addEventListener(ProgressEvent.STANDARD_ERROR_DATA, onErrorData); 
                        process.addEventListener(ProgressEvent.PROGRESS, onOutputData); 
                        process.addEventListener(ProgressEvent.SOCKET_DATA, onOutputData); 
                        process.addEventListener(IOErrorEvent.STANDARD_OUTPUT_IO_ERROR, onIOError);
                        process.addEventListener(IOErrorEvent.STANDARD_ERROR_IO_ERROR, onIOError);
                    } else {
                        trace("process not found");
                    }
                } else {
                    trace("Native Process not supported");
                }
            }

            private function startNativeProcess():void {
                processArgs = new Vector.<String>();
                processArgs.push("-I rc");
                processArgs.push("-vvv"); // verbose debug output
                processArgs.push("--sout");

                // -------TO WRITE TO A FILE ----------
                // file to playback from
                //var output:File = File.desktopDirectory.resolvePath("stream.flv");
                //var outputPath:String = output.nativePath;
                //processArgs.push("#transcode{vcodec=FLV1}:std{access=file,mux=ffmpeg{mux=flv},dst=" + outputPath + "}");

                processArgs.push("#transcode{vcodec=FLV1,acodec=mp3}:gather:std{access=file,mux=flv,dst=-}");
                processArgs.push("--sout-keep");

                // ------VARIATIONS-------
                //processArgs.push("#transcode{vcodec=FLV1,acodec=mp3}:std{access=file,mux=flv,dst=-}");
                //processArgs.push("#transcode{vcodec=h264,vb=512,acodec=mp3,ab=128,samplerate=44100}:std{mux=ffmpeg{mux=flv},access=file,dst=-}");

                var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo();
                nativeProcessStartupInfo.executable = processExe;
                nativeProcessStartupInfo.arguments = processArgs;
                process.start(nativeProcessStartupInfo);

                // add video to playlist and play
                process.standardInput.writeUTFBytes("add " + videoPath + " \n" );
                process.standardInput.writeUTFBytes("play" + "\n" );
            }

            public function onOutputData(event:ProgressEvent):void { 
                if (process && process.running){
                    if (process.standardOutput.bytesAvailable){
                        var videoStream:ByteArray = new ByteArray();
                        process.standardOutput.readBytes(videoStream,0, process.standardOutput.bytesAvailable);

                        dataIn = videoStream.length;
                        dataTotal+= dataIn;
                        report.text = String("Current Bytes: " + dataIn + "\t Total Bytes: "+ dataTotal);

                        if (videoStream.length){
                            ns.appendBytes(videoStream);
                        }
                        //trace(ns.info);
                    }   
                }
            }

            private function errorHandler(e:AsyncErrorEvent):void {
                trace('ERROR: ' + e.text);
            }

            private function connStatusHandler(e:NetStatusEvent):void {
                trace('CONN_STATUS: ' + e.info.code);

                switch(e.info.code){
                    case "NetConnection.Connect.Success":
                        //onFinishSetup();
                        break;
                }
            }

            private function streamStatusHandler(e:NetStatusEvent):void {
                trace('STREAM_STATUS: ' + e.info.code);
            }

            private function streamMetadataHandler(info:Object):void {
                for (var key:String in info) {
                    trace("STREAM_METADATA: " + key + "=" + info[key]);
                }               
            }

            public function onErrorData(event:ProgressEvent):void {
                if (process && process.running){
                    trace(process.standardError.readUTFBytes(process.standardError.bytesAvailable));
                }
            }
            public function onIOError(event:IOErrorEvent):void {
                trace(event.toString());
            }

            private function onMetaDataHandler(metadata:Object):void {
                trace("### Begin Metadata listing : FLV Entries ### "  );
                for (var entry:* in metadata) 
                {
                    var value:Object = metadata[ entry ];
                    trace(" > " + entry + " : " + value);
                }
                trace("### End of Metadata listing for this FLV ### "  );
            }
        ]]>
    </fx:Script>

    <s:Label id="report" x="25" y="25" fontSize="18" />
</s:WindowedApplication>

Answer 1

在您的其他问题的评论中，您询问了我的想法：

\n\n

我注意到你的代码中你正在 OSX 环境下运行 VLC 进程。
\n在 Windows PC 上请注意，-I rc稍后不会响应standardInput发送的命令。我是 Windows 用户，因此无法帮助解决该部分。

\n\n

尝试使用--no-rc-fake-tty或--rc-fake-tty，VLC在PC上仍然没有响应stdout。

\n\n

您想在 VLC 中进行播放和搜索，但在 AS3 中观看结果（就像投影屏幕），对吧？但我什至不确定 VLC 是否会从您选择的时间戳等开始为您返回 FLV 标签（通过寻找您正在访问特定时间戳和相关 a/v 数据的 FLV 标签）...

\n\n

其他 FFmpeg/Mencoder 支持的播放器（例如我测试的 MPlayer）仅在播放期间发回“状态”文本数据stdout（因此无法馈送到NetStream解码器进行显示）。

\n\n

\n

我能够粗略地解析stdout来自 VLC 的传入流。我想查看 FLV 标头数据是否正在发送 \xe2\x80\x93，看起来确实如此。我不知道它的格式是否正确等等。

\n

\n\n

检查字节：（有效的 FLV 标头以 开头46 4C 56 01 05 00 00 00 09 00 00 00 00）

\n\n

只需使用以下函数的“字节检查”结果的复制粘贴来更新您的问题。然后更容易告诉您它是否可以玩或者您可能需要一些替代方案。

\n\n

1）设置一些公共（或私有）变量...

\n\n

\n
• 做一个public var temp_String : String = "";
\n
• 做一个public var videoStream:ByteArray = new ByteArray();
\n

\n\n

2）onOutputData用下面的代码替换你的函数...

\n\n

public function onOutputData(event:ProgressEvent):void \n{ \n    if (process && process.running)\n    {\n        if (process.standardOutput.bytesAvailable)\n        {\n            //# make a private/public bytearray outside of this function \n            //var videoStream:ByteArray = new ByteArray();\n\n            process.standardOutput.readBytes(videoStream, videoStream.length, process.standardOutput.bytesAvailable);\n\n            dataIn = process.standardOutput.bytesAvailable; \n            dataTotal += dataIn;\n            //report.text = String("Current Bytes: " + dataIn + "\\t Total Bytes: "+ dataTotal);\n\n            if (videoStream.length >= 1000 )\n            {\n                //ns.appendBytes(videoStream);\n\n                temp_String = bytes_toString(videoStream);\n                trace("bytes checking : " + "\\n");\n                trace( temp_String ); //see hex of FLV bytes\n\n                //# temporary pausing of progress events \n                process.removeEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, onOutputData);\n            }\n            //trace(ns.info);\n        }\n    }\n}\n

\n\n

支持功能bytes_toString代码：

\n\n

public function bytes_toString ( ba:ByteArray ) : String\n{\n    var str_Hex:String = "";    var len:uint = ba.length;\n\n    ba.position = 0;\n\n    for (var i:uint = 0; i < len; i++) \n    {\n        var n:String=ba.readUnsignedByte().toString(16); \n\n        if(n.length<2) //padding\n        { n="0"+n; }    str_Hex += n ;\n    }\n\n    return str_Hex.toUpperCase();\n}\n

\n\n

其他一些注意事项：

\n\n

每次触发进度事件stdout一次仅捕获 32kb / 64kb 的传入字节数据包。

\n\n

您可以将您的videoStream:ByteArray = new ByteArray();代码置于 ProgressEvent 之外，以便每个事件触发都不会生成新的 byteArray（这会丢弃完整 FLV 标记稍后可能需要的旧数据）。

\n\n

不要将每个数据包写入该0位置，因为这会覆盖现有数据。添加到现有的末尾作为videoStream.length新的书写位置。

\n\n

process.standardOutput.readBytes(videoStream, videoStream.length, process.standardOutput.bytesAvailable);\n

\n\n

也if (videoStream.length){ ns.appendBytes(videoStream); }有点危险。如果您附加得太快，任何不完整的数据（标头、帧或其他数据）都会堵塞 NetStream 解码器。除非您重置所有内容并重新开始（重新附加完整 FLV 标头、全帧标签等字节），否则它不会重新启动。

\n