XSLT函数返回不同的结果[Saxon-EE vs Saxon-HE/PE]

Question

我目前正在使用各种版本的Saxon-Processor进行纯XSL转换.下面是我的简短样式表,简化了我的问题的需求:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:foo="bar">

    <xsl:output encoding="UTF-8" method="text"/>

    <xsl:template match="/">
        <xsl:text>Call of func_1: </xsl:text>        
        <xsl:value-of select="foo:func_1()"/>

        <xsl:text>&#xA;Call of func_1: </xsl:text>
        <xsl:value-of select="foo:func_1()"/>

        <xsl:text>&#xA;Call of func_1: </xsl:text>
        <xsl:value-of select="foo:func_1()"/>

        <xsl:text>&#xA;Call of func_2: </xsl:text>
        <xsl:value-of select="foo:func_2()"/>
    </xsl:template>

    <xsl:function name="foo:func_1" as="xs:string">
        <!-- do some other stuff -->
        <xsl:value-of select="foo:func_2()"/>
    </xsl:function>

    <xsl:function name="foo:func_2" as="xs:string">
        <xsl:variable name="node">
            <xsl:comment/>
        </xsl:variable>
        <xsl:sequence select="generate-id($node)"/>
    </xsl:function>

</xsl:stylesheet>

描述

foo:func_1是一个包装函数,用于返回第二个函数的值+执行其他操作,可以忽略.这个函数调用的概念是强制性的!

foo:func_2为元素生成唯一的id.此元素在名为"node"的本地范围变量中创建.

基于Saxon版本的不同结果

预期结果:

Call of func_1: d2
Call of func_1: d3
Call of func_1: d4
Call of func_2: d5

Saxon-EE 9.6.0.7/Saxon-EE 9.6.0.5结果

Call of func_1: d2
Call of func_1: d2
Call of func_1: d2
Call of func_2: d3

Saxon-HE 9.6.0.5/Saxon-PE 9.6.0.5/Saxon-EE 9.5.1.6/Saxon-HE 9.5.1.6结果

like expected

问题/进一步深入

我尽我所能调试了这个问题.如果我将xsl:value-ofin函数"func_1" 更改为xsl:sequence,则所有版本[如预期]的结果将相同.但那不是我的意图!

我想了解,撒克逊版本xsl:value-of和xsl:sequence整个版本之间有什么区别.有没有"隐藏"的缓存？什么是一起工作的正确方法xsl:sequence,并xsl:value-of在我的案件.[顺便说一下:我已经知道了,value-of创建了一个带有select语句结果的文本节点.sequence可以是对节点或原子值的引用.不解决我的问题afaik]

Answer 1

这是一个长期存在且比较深刻的问题。在纯函数语言中，使用相同的参数调用纯函数两次总是会产生相同的结果。这使得许多优化成为可能，例如，如果参数不变，则将函数调用从循环中拉出，或者如果函数调用不是递归的，则内联函数调用。不幸的是，XSLT 和 XQuery 函数并不是完全纯粹的函数式：特别是，它们被定义为：如果函数创建新节点，则调用该函数两次会产生不同的节点（f() is f()返回false）。

Saxon 优化器非常努力地在这些约束内尽可能地进行优化，特别是通过识别创建新节点的函数并避免对此类函数进行激进的优化。

但规范本身并不是 100% 规范的。例如，如果在您的示例中存在一个不依赖于函数参数的局部变量，我认为规范为实现提供了关于该变量的值在每次评估中是否是同一节点或者是一个新节点的许可。

正如 Martin 所说，新的 XSLT 3.0 属性 new-each-time 试图控制这一点：如果您确实希望每次调用函数时都有一个新节点，则应该指定new-each-time="yes"。

笔记：

这里发生的具体优化（您可以通过使用 -explain 选项运行来看到）是 func_2 首先被内联，然后它的主体被提取到全局变量中。有些版本正在这样做，而另一些则没有——它可能对微小的变化非常敏感。最好的建议是不要依赖具有此类副作用的函数。如果您解释了真正的问题，这将会有所帮助，那么也许我们可以找到一种对语言语义中的边缘情况不太敏感的方法。